This file documents SLIB, the portable Scheme library.

Copyright (C) 1993 Todd R. Eigenschink Copyright (C) 1993, 1994, 1995 Aubrey Jaffer

Permission is granted to make and distribute verbatim copies of this manual provided the copyright notice and this permission notice are preserved on all copies.

Permission is granted to copy and distribute modified versions of this manual under the conditions for verbatim copying, provided that the entire resulting derived work is distributed under the terms of a permission notice identical to this one.

Permission is granted to copy and distribute translations of this manual into another language, under the above conditions for modified versions, except that this permission notice may be stated in a translation approved by the author.

This file documents SLIB, the portable Scheme library.

Good Engineering is 1% inspiration and 99% documentation.
=========================================================

Herein lies the good part.  Many thanks to Todd Eigenschink <eigenstr@CS.Rose-Hulman.Edu> (who thanks Dave Love <D.Love@dl.ac.uk>) for creating slib.texi.  I have learned much from their example.

Aubrey Jaffer jaffer@ai.mit.edu

Overview
********

SLIB is a portable Scheme library meant to provide compatibility and utility functions for all standard Scheme implementations, and fixes several implementations which are non-conforming.  SLIB conforms to Revised^4 Report on the Algorithmic Language Scheme and the IEEE P1178 specification.  SLIB supports Unix and similar systems, VMS, and MS-DOS.

For a summary of what each file contains, see the file README. For a list of the features that have changed since the last SLIB release, see the file ANNOUNCE.  For a list of the features that have changed over time, see the file ChangeLog.

The maintainer can be reached as jaffer@ai.mit.edu or Aubrey Jaffer, 84 Pleasant St., Wakefield, MA 01880-1846.

Installation
============

Check the manifest in README to find a configuration file for your Scheme implementation.  Initialization files for most IEEE P1178 compliant Scheme Implementations are included with this distribution.

If the Scheme implementation supports getenv, then the value of the shell environment variable SCHEME_LIBRARY_PATH will be used for (library-vicinity) if it is defined.  Currently, Chez, Elk, MITScheme, scheme->c, VSCM, and SCM support getenv.

You should check the definitions of software-type, scheme-implementation-version, implementation-vicinity, and library-vicinity in the initialization file.  There are comments in the file for how to configure it.

Once this is done you can modify the startup file for your Scheme implementation to load this initialization file.  SLIB is then installed.

Multiple implementations of Scheme can all use the same SLIB directory. Simply configure each implementation's initialization file as outlined above.

The SCM implementation does not require any initialization file as SLIB support is already built in to SCM.  See the documentation with SCM for installation instructions.

SLIB includes methods to create heap images for the VSCM and Scheme48 implementations.  The instructions for creating a VSCM image are in comments in vscm.init.  To make a Scheme48 image, cd to the SLIB directory and type make slib48.  This will also create a shell script with the name slib48 which will invoke the saved image.

Porting
=======

If there is no initialization file for your Scheme implementation, you will have to create one.  Your Scheme implementation must be largely compliant with IEEE Std 1178-1990 or Revised^4 Report on the Algorithmic Language Scheme to support SLIB.

Template.scm is an example configuration file.  The comments inside will direct you on how to customize it to reflect your system. Give your new initialization file the implementation's name with .init appended.  For instance, if you were porting foo-scheme then the initialization file might be called foo.init.

Your customized version should then be loaded as part of your scheme implementation's initialization.  It will load require.scm (see Require) from the library; this will allow the use of provide, provided?, and require along with the vicinity functions (vicinity functions are documented in the section on Require.  See Require).  The rest of the library will then be accessible in a system independent fashion.

Please mail new working configuration files to jaffer@ai.mit.edu so that they can be included in the SLIB distribution.

Coding Standards
================

All library packages are written in IEEE P1178 Scheme and assume that a configuration file and require.scm package have already been loaded.  Other versions of Scheme can be supported in library packages as well by using, for example, (provided? 'rev3-report) or (require 'rev3-report) (see Require).

require.scm defines *catalog*, an association list of module names and filenames.  When a new package is added to the library, an entry should be added to require.scm.  Local packages can also be added to *catalog* and even shadow entries already in the table.

The module name and : should prefix each symbol defined in the package.  Definitions for external use should then be exported by having (define foo module-name:foo).

Submitted code should not duplicate routines which are already in SLIB files.  Use require to force those features to be supported in your package.  Care should be taken that there are no circularities in the requires and loads between the library packages.

Documentation should be provided in Emacs Texinfo format if possible, But documentation must be provided.

Your package will be released sooner with SLIB if you send me a file which tests your code.  Please run this test before you send me the code!

Modifications
-------------

Please document your changes.  A line or two for ChangeLog is sufficient for simple fixes or extensions.  Look at the format of ChangeLog to see what information is desired.  Please send me diff files from the latest SLIB distribution (remember to send diffs of slib.texi and ChangeLog).  This makes for less email traffic and makes it easier for me to integrate when more than one person is changing a file (this happens a lot with slib.texi and *.init files).

If someone else wrote a package you want to significantly modify, please try to contact the author, who may be working on a new version.  This will insure against wasting effort on obsolete versions.

Please do not reformat the source code with your favorite beautifier, make 10 fixes, and send me the resulting source code.  I do not have the time to fish through 10000 diffs to find your 10 real fixes.

Copyrights
==========

This section has instructions for SLIB authors regarding copyrights.

Each package in SLIB must either be in the public domain, or come with a statement of terms permitting users to copy, redistribute and modify it. The comments at the beginning of require.scm and macwork.scm illustrate copyright and appropriate terms.

If your code or changes amount to less than about 10 lines, you do not need to add your copyright or send a disclaimer.

Putting code into the Public Domain
-----------------------------------

In order to put code in the public domain you need to sign a copyright disclaimer and send it to the SLIB maintainer, Aubrey Jaffer, 84 Pleasant St., Wakefield, MA 01880-1846.

     I, NAME, hereby affirm that I have placed the software package NAME in the public domain.

     I affirm that I am the sole author and sole copyright holder for the software package, that I have the right to place this software package in the public domain, and that I will do nothing to undermine this status in the future.

     SIGNATURE AND DATE

This wording assumes that you are the sole author.  If you are not the sole author, the wording needs to be different.  If you don't want to be bothered with sending a letter every time you release or modify a module, make your letter say that it also applies to your future revisions of that module.

Make sure no employer has any claim to the copyright on the work you are submitting.  If there is any doubt, create a copyright disclaimer and have your employer sign it.  Mail the signed disclaim to Aubrey Jaffer, 84 Pleasant St., Wakefield, MA 01880-1846.  An example disclaimer follows.

Explicit copying terms
----------------------

If you submit more than about 10 lines of code which you are not placing into the Public Domain (by sending me a disclaimer) you need to:

  * Arrange that your name appears in a copyright line for the appropriate year.   Multiple copyright lines are acceptable.

  * With your copyright line, specify any terms you require to be different from those already in the file.

  * Make sure no employer has any claim to the copyright on the work you are submitting.  If there is any doubt, create a copyright disclaimer and have your employer sign it.  Mail the signed disclaim to Aubrey Jaffer, 84 Pleasant St., Wakefield, MA 01880-1846.

Example: Company Copyright Disclaimer
-------------------------------------

This disclaimer should be signed by a vice president or general manager of the company.  If you can't get at them, anyone else authorized to license out software produced there will do.  Here is a sample wording:

     EMPLOYER Corporation hereby disclaims all copyright interest in the program PROGRAM written by NAME.

     EMPLOYER Corporation affirms that it has no other intellectual property interest that would undermine this release, and will do nothing to undermine it in the future.

     SIGNATURE AND DATE,
     NAME, TITLE, EMPLOYER Corporation

Please mail the signed disclaimers to:

Aubrey Jaffer
84 Pleasant St.
Wakefield, MA 01880-1846

Manual Conventions
==================

Things that are labeled as Functions are called for their return values. Things that are labeled as Procedures are called primarily for their side effects.

All examples throughout this text were produced using the scm Scheme implementation.

At the beginning of each section, there is a line that looks something like

(require 'feature).

This means that, in order to use feature, you must include the line (require 'feature) somewhere in your code prior to the use of that feature.  require will make sure that the feature is loaded.

Data Structures
***************

Arrays
======

(require 'array)

 -- Function: array? obj
     Returns #t if the OBJ is an array, and #f if not.

 -- Function: make-array initial-value bound1 bound2 ...
     Creates and returns an array that has as many dimensins as there are BOUNDs and fills it with INITIAL-VALUE.

When constructing an array, BOUND is either an inclusive range of indices expressed as a two element list, or an upper bound expressed as a single integer.  So

     (make-array 'foo 3 3) == (make-array 'foo '(0 2) '(0 2))

 -- Function: make-shared-array array mapper bound1 bound2 ...
     make-shared-array can be used to create shared subarrays of other arrays.  The MAPPER is a function that translates coordinates in the new array into coordinates in the old array.  A MAPPER must be linear, and its range must stay within the bounds of the old array, but it can be otherwise arbitrary.  A simple example:

          (define fred (make-array #f 8 8))
          (define freds-diagonal
            (make-shared-array fred (lambda (i) (list i i)) 8))
          (array-set! freds-diagonal 'foo 3)
          (array-ref fred 3 3)
             => FOO
          (define freds-center
            (make-shared-array fred (lambda (i j) (list (+ 3 i) (+ 3 j)))
                               2 2))
          (array-ref freds-center 0 0)
             => FOO

 -- Function: array-rank obj
     Returns the number of dimensions of OBJ.  If OBJ is not an array, 0 is returned.

 -- Function: array-shape array
     array-shape returns a list of inclusive bounds.  So:

          (array-shape (make-array 'foo 3 5))
             => ((0 2) (0 4))

 -- Function: array-dimensions array
     array-dimensions is similar to array-shape but replaces elements with a 0 minimum with one greater than the maximum. So:

          (array-dimensions (make-array 'foo 3 5))
             => (3 5)

 -- Procedure: array-in-bounds? array index1 index2 ...
     Returns #t if its arguments would be acceptable to array-ref.

 -- Function: array-ref array index1 index2 ...
     Returns the element at the (INDEX1, INDEX2) element in ARRAY.

 -- Procedure: array-set! array new-value index1 index2 ...

 -- Function: array-1d-ref array index
 -- Function: array-2d-ref array index index
 -- Function: array-3d-ref array index index index

 -- Procedure: array-1d-set! array new-value index
 -- Procedure: array-2d-set! array new-value index index
 -- Procedure: array-3d-set! array new-value index index index

The functions are just fast versions of array-ref and array-set! that take a fixed number of arguments, and perform no bounds checking.

If you comment out the bounds checking code, this is about as efficient as you could ask for without help from the compiler.

An exercise left to the reader: implement the rest of APL.

Array Mapping
=============

(require 'array-for-each)

 -- Function: array-map! <array0> <proc> <array1> ...
     ARRAY1, ... must have the same number of dimensions as ARRAY0 and have a range for each index which includes the range for the corresponding index in ARRAY0.  PROC is applied to each tuple of elements of ARRAY1 ... and the result is stored as the corresponding element in ARRAY0.  The value returned is unspecified.  The order of application is unspecified.

 -- Function: array-for-each PROC ARRAY0 ...
     PROC is applied to each tuple of elements of ARRAY0 ... in row-major order.  The value returned is unspecified.

 -- Function: array-indexes ARRAY
     Returns an array of lists of indexes for ARRAY such that, if LI is a list of indexes for which ARRAY is defined, (equal? LI (apply array-ref (array-indexes ARRAY) LI)).

Association Lists
=================

(require 'alist)

Alist functions provide utilities for treating a list of key-value pairs as an associative database.  These functions take an equality predicate, PRED, as an argument.  This predicate should be repeatable, symmetric, and transitive.

Alist functions can be used with a secondary index method such as hash tables for improved performance.

 -- Function: predicate->asso pred
     Returns an association function (like assq, assv, or assoc) corresponding to PRED.  The returned function returns a key-value pair whose key is pred-equal to its first argument or #f if no key in the alist is PRED-equal to the first argument.

 -- Function: alist-inquirer pred
     Returns a procedure of 2 arguments, ALIST and KEY, which returns the value associated with KEY in ALIST or #f if KEY does not appear in ALIST.

 -- Function: alist-associator pred
     Returns a procedure of 3 arguments, ALIST, KEY, and VALUE, which returns an alist with KEY and VALUE associated.  Any previous value associated with KEY will be lost.  This returned procedure may or may not have side effects on its ALIST argument.  An example of correct usage is:

          (define put (alist-associator string-ci=?))
          (define alist '())
          (set! alist (put alist "Foo" 9))

 -- Function: alist-remover pred
     Returns a procedure of 2 arguments, ALIST and KEY, which returns an alist with an association whose KEY is key removed. This returned procedure may or may not have side effects on its ALIST argument.  An example of correct usage is:

          (define rem (alist-remover string-ci=?))
          (set! alist (rem alist "foo"))

 -- Function: alist-map proc alist
     Returns a new association list formed by mapping PROC over the keys and values of ALIST.   PROC must be a function of 2 arguments which returns the new value part.

 -- Function: alist-for-each proc alist
     Applies PROC to each pair of keys and values of ALIST. PROC must be a function of 2 arguments.  The returned value is unspecified.

Collections
===========

(require 'collect)

Routines for managing collections.  Collections are aggregate data structures supporting iteration over their elements, similar to the Dylan(TM) language, but with a different interface.  They have elements indexed by corresponding keys, although the keys may be implicit (as with lists).

New types of collections may be defined as YASOS objects (see Yasos). They must support the following operations:

  * (collection? SELF) (always returns #t);

  * (size SELF) returns the number of elements in the collection;

  * (print SELF PORT) is a specialized print operation for the collection which prints a suitable representation on the given PORT or returns it as a string if PORT is #t;

  * (gen-elts SELF) returns a thunk which on successive invocations yields elements of SELF in order or gives an error if it is invoked more than (size SELF) times;

  * (gen-keys SELF) is like gen-elts, but yields the collection's keys in order.

They might support specialized for-each-key and for-each-elt operations.

 -- Function: collection? obj
     A predicate, true initially of lists, vectors and strings.  New sorts of collections must answer #t to collection?.

 -- Procedure: map-elts proc . collections
 -- Procedure: do-elts proc . collections
     PROC is a procedure taking as many arguments as there are COLLECTIONS (at least one).  The COLLECTIONS are iterated over in their natural order and PROC is applied to the elements yielded by each iteration in turn.  The order in which the arguments are supplied corresponds to te order in which the COLLECTIONS appear. do-elts is used when only side-effects of PROC are of interest and its return value is unspecified.  map-elts returns a collection (actually a vector) of the results of the applications of PROC.

     Example:

          (map-elts + (list 1 2 3) (vector 1 2 3))
             => #(2 4 6)

 -- Procedure: map-keys proc . collections
 -- Procedure: do-keys proc . collections
     These are analogous to map-elts and do-elts, but each iteration is over the COLLECTIONS' keys rather than their elements.

     Example:

          (map-keys + (list 1 2 3) (vector 1 2 3))
             => #(0 2 4)

 -- Procedure: for-each-key collection proc
 -- Procedure: for-each-elt collection proc
     These are like do-keys and do-elts but only for a single collection; they are potentially more efficient.

 -- Function: reduce proc seed . collections
     A generalization of the list-based comlist:reduce-init (see Lists as sequences) to collections which will shadow the list-based version if (require 'collect) follows (require 'common-list-functions) (see Common List Functions).

     Examples:

          (reduce + 0 (vector 1 2 3))
             => 6
          (reduce union '() '((a b c) (b c d) (d a)))
             => (c b d a).

 -- Function: any? pred . collections
     A generalization of the list-based some (see Lists as sequences) to collections.

     Example:

          (any? odd? (list 2 3 4 5))
             => #t

 -- Function: every? pred . collections
     A generalization of the list-based every (see Lists as sequences) to collections.

     Example:

          (every? collection? '((1 2) #(1 2)))
             => #t

 -- Function: empty? collection
     Returns #t iff there are no elements in COLLECTION.

     (empty? COLLECTION) == (zero? (size COLLECTION))

 -- Function: size collection
     Returns the number of elements in COLLECTION.

 -- Function: Setter list-ref
     See Setters for a definition of setter.  N.B. (setter list-ref) doesn't work properly for element 0 of a list.

Here is a sample collection: simple-table which is also a table.

     (define-predicate TABLE?)
     (define-operation (LOOKUP table key failure-object))
     (define-operation (ASSOCIATE! table key value)) ;; returns key
     (define-operation (REMOVE! table key))          ;; returns value

     (define (MAKE-SIMPLE-TABLE)
       (let ( (table (list)) )
         (object
          ;; table behaviors
          ((TABLE? self) #t)
          ((SIZE self) (size table))
          ((PRINT self port) (format port "#<SIMPLE-TABLE>"))
          ((LOOKUP self key failure-object)
           (cond
            ((assq key table) => cdr)
            (else failure-object)
            ))
          ((ASSOCIATE! self key value)
           (cond
            ((assq key table)
             => (lambda (bucket) (set-cdr! bucket value) key))
            (else
             (set! table (cons (cons key value) table))
             key)
            ))
          ((REMOVE! self key);; returns old value
           (cond
            ((null? table) (slib:error "TABLE:REMOVE! Key not found: " key))
            ((eq? key (caar table))
             (let ( (value (cdar table)) )
               (set! table (cdr table))
               value)
             )
            (else
             (let loop ( (last table) (this (cdr table)) )
               (cond
                ((null? this)
                 (slib:error "TABLE:REMOVE! Key not found: " key))
                ((eq? key (caar this))
                 (let ( (value (cdar this)) )
                   (set-cdr! last (cdr this))
                   value)
                 )
                (else
                 (loop (cdr last) (cdr this)))
                ) ) )
            ))
          ;; collection behaviors
          ((COLLECTION? self) #t)
          ((GEN-KEYS self) (collect:list-gen-elts (map car table)))
          ((GEN-ELTS self) (collect:list-gen-elts (map cdr table)))
          ((FOR-EACH-KEY self proc)
           (for-each (lambda (bucket) (proc (car bucket))) table)
           )
          ((FOR-EACH-ELT self proc)
           (for-each (lambda (bucket) (proc (cdr bucket))) table)
           )
          ) ) )

Dynamic Data Type
=================

(require 'dynamic)

 -- Function: make-dynamic obj
     Create and returns a new dynamic whose global value is OBJ.

 -- Function: dynamic? obj
     Returns true if and only if OBJ is a dynamic.  No object satisfying dynamic? satisfies any of the other standard type predicates.

 -- Function: dynamic-ref dyn
     Return the value of the given dynamic in the current dynamic environment.

 -- Procedure: dynamic-set! dyn obj
     Change the value of the given dynamic to OBJ in the current dynamic environment.  The returned value is unspecified.

 -- Function: call-with-dynamic-binding dyn obj thunk
     Invoke and return the value of the given thunk in a new, nested dynamic environment in which the given dynamic has been bound to a new location whose initial contents are the value OBJ.  This dynamic environment has precisely the same extent as the invocation of the thunk and is thus captured by continuations created within that invocation and re-established by those continuations when they are invoked.

The dynamic-bind macro is not implemented.

Hash Tables
===========

(require 'hash-table)

 -- Function: predicate->hash pred
     Returns a hash function (like hashq, hashv, or hash) corresponding to the equality predicate PRED. PRED should be eq?, eqv?, equal?, =, char=?, char-ci=?, string=?, or string-ci=?.

A hash table is a vector of association lists.

 -- Function: make-hash-table k
     Returns a vector of K empty (association) lists.

Hash table functions provide utilities for an associative database. These functions take an equality predicate, PRED, as an argument. PRED should be eq?, eqv?, equal?, =, char=?, char-ci=?, string=?, or string-ci=?.

 -- Function: predicate->hash-asso pred
     Returns a hash association function of 2 arguments, KEY and HASHTAB, corresponding to PRED.  The returned function returns a key-value pair whose key is PRED-equal to its first argument or #f if no key in HASHTAB is PRED-equal to the first argument.

 -- Function: hash-inquirer pred
     Returns a procedure of 3 arguments, hashtab and key, which returns the value associated with key in hashtab or #f if key does not appear in hashtab.

 -- Function: hash-associator pred
     Returns a procedure of 3 arguments, HASHTAB, KEY, and VALUE, which modifies HASHTAB so that KEY and VALUE associated.  Any previous value associated with KEY will be lost.

 -- Function: hash-remover pred
     Returns a procedure of 2 arguments, HASHTAB and KEY, which modifies HASHTAB so that the association whose key is KEY is removed.

 -- Function: hash-map proc hash-table
     Returns a new hash table formed by mapping PROC over the keys and values of HASH-TABLE.  PROC must be a function of 2 arguments which returns the new value part.

 -- Function: hash-for-each proc hash-table
     Applies PROC to each pair of keys and values of HASH-TABLE. PROC must be a function of 2 arguments.  The returned value is unspecified.

Hashing
=======

(require 'hash)

These hashing functions are for use in quickly classifying objects. Hash tables use these functions.

 -- Function: hashq obj k
 -- Function: hashv obj k
 -- Function: hash obj k
     Returns an exact non-negative integer less than K.  For each non-negative integer less than K there are arguments OBJ for which the hashing functions applied to OBJ and K returns that integer.

     For hashq, (eq? obj1 obj2) implies (= (hashq obj1 k) (hashq obj2)).

     For hashv, (eqv? obj1 obj2) implies (= (hashv obj1 k) (hashv obj2)).

     For hash, (equal? obj1 obj2) implies (= (hash obj1 k) (hash obj2)).

     hash, hashv, and hashq return in time bounded by a constant.  Notice that items having the same hash implies the items have the same hashv implies the items have the same hashq.

(require 'sierpinski)

 -- Function: make-sierpinski-indexer max-coordinate
     Returns a procedure (eg hash-function) of 2 numeric arguments which preserves nearness in its mapping from NxN to N.

     MAX-COORDINATE is the maximum coordinate (a positive integer) of a population of points.  The returned procedures is a function that takes the x and y coordinates of a point, (non-negative integers) and returns an integer corresponding to the relative position of that point along a Sierpinski curve.  (You can think of this as computing a (pseudo-) inverse of the Sierpinski spacefilling curve.)

     Example use: Make an indexer (hash-function) for integer points lying in square of integer grid points [0,99]x[0,99]:

          (define space-key (make-sierpinski-indexer 100))

     Now let's compute the index of some points:

          (space-key 24 78)               => 9206
          (space-key 23 80)               => 9172

     Note that locations (24, 78) and (23, 80) are near in index and therefore, because the Sierpinski spacefilling curve is continuous, we know they must also be near in the plane.  Nearness in the plane does not, however, necessarily correspond to nearness in index, although it tends to be so.

     Example applications:

          Sort points by Sierpinski index to get heuristic solution to travelling salesman problem.  For details of performance, see L. Platzman and J. Bartholdi, "Spacefilling curves and the Euclidean travelling salesman problem", JACM 36(4):719--737 (October 1989) and references therein.

          Use Sierpinski index as key by which to store 2-dimensional data in a 1-dimensional data structure (such as a table).  Then locations that are near each other in 2-d space will tend to be near each other in 1-d data structure; and locations that are near in 1-d data structure will be near in 2-d space.  This can significantly speed retrieval from secondary storage because contiguous regions in the plane will tend to correspond to contiguous regions in secondary storage.  (This is a standard technique for managing CAD/CAM or geographic data.)

(require 'soundex)

 -- Function: soundex name
     Computes the soundex hash of NAME.  Returns a string of an initial letter and up to three digits between 0 and 6.  Soundex supposedly has the property that names that sound similar in normal English pronunciation tend to map to the same key.

     Soundex was a classic algorithm used for manual filing of personal records before the advent of computers.  It performs adequately for English names but has trouble with other nationalities.

     See Knuth, Vol. 3 Sorting and searching, pp 391--2

     To manage unusual inputs, soundex omits all non-alphabetic characters.  Consequently, in this implementation:

          (soundex <string of blanks>)    => ""
          (soundex "")                    => ""

     Examples from Knuth:

          (map soundex '("Euler" "Gauss" "Hilbert" "Knuth"
                                 "Lloyd" "Lukasiewicz"))
                  => ("E460" "G200" "H416" "K530" "L300" "L222")

          (map soundex '("Ellery" "Ghosh" "Heilbronn" "Kant"
                                  "Ladd" "Lissajous"))
                  => ("E460" "G200" "H416" "K530" "L300" "L222")

     Some cases in which the algorithm fails (Knuth):

          (map soundex '("Rogers" "Rodgers"))     => ("R262" "R326")

          (map soundex '("Sinclair" "St. Clair")) => ("S524" "S324")

          (map soundex '("Tchebysheff" "Chebyshev")) => ("T212" "C121")

Chapter Ordering
================

(require 'chapter-order)

The chap: functions deal with strings which are ordered like chapter numbers (or letters) in a book.  Each section of the string consists of consecutive numeric or consecutive aphabetic characters of like case.

 -- Function: chap:string<? string1 string2
     Returns #t if the first non-matching run of alphabetic upper-case or the first non-matching run of alphabetic lower-case or the first non-matching run of numeric characters of STRING1 is string<? than the corresponding non-matching run of characters of STRING2.

          (chap:string<? "a.9" "a.10")                    => #t
          (chap:string<? "4c" "4aa")                      => #t
          (chap:string<? "Revised^{3.99}" "Revised^{4}")  => #t

 -- Function: chap:string>? string1 string2
 -- Function: chap:string<=? string1 string2
 -- Function: chap:string>=? string1 string2
     Implement the corresponding chapter-order predicates.

 -- Function: chap:next-string string
     Returns the next string in the chapter order.  If STRING has no alphabetic or numeric characters, (string-append STRING "0") is returnd.  The argument to chap:next-string will always be chap:string<? than the result.

          (chap:next-string "a.9")                => "a.10"
          (chap:next-string "4c")                 => "4d"
          (chap:next-string "4z")                 => "4aa"
          (chap:next-string "Revised^{4}")        => "Revised^{5}"

Macroless Object System
=======================

(require 'object)

This is the Macroless Object System written by Wade Humeniuk (whumeniu@datap.ca).  Conceptual Tributes: Yasos, MacScheme's %object, CLOS, Lack of R4RS macros.

Concepts
--------

OBJECT
     An object is an ordered association-list (by eq?) of methods (procedures).  Methods can be added (make-method!), deleted (unmake-method!) and retrieved (get-method).  Objects may inherit methods from other objects.  The object binds to the environment it was created in, allowing closures to be used to hide private procedures and data.

GENERIC-METHOD
     A generic-method associates (in terms of eq?) object's method. This allows scheme function style to be used for objects.  The calling scheme for using a generic method is (generic-method object param1 param2 ...).

METHOD
     A method is a procedure that exists in the object.  To use a method get-method must be called to look-up the method.  Generic methods implement the get-method functionality.  Methods may be added to an object associated with any scheme obj in terms of eq?

GENERIC-PREDICATE
     A generic method that returns a boolean value for any scheme obj.

PREDICATE
     A object's method asscociated with a generic-predicate. Returns #t.

Procedures
----------

 -- Function: make-object ancestor ...
     Returns an object.  Current object implementation is a tagged vector. ANCESTORs are optional and must be objects in terms of object?. ANCESTORs methods are included in the object.  Multiple ANCESTORs might associate the same generic-method with a method. In this case the method of the ANCESTOR first appearing in the list is the one returned by get-method.

 -- Function: object? obj
     Returns boolean value whether OBJ was created by make-object.

 -- Function: make-generic-method exception-procedure
     Returns a procedure which be associated with an object's methods.  If EXCEPTION-PROCEDURE is specified then it is used to process non-objects.

 -- Function: make-generic-predicate
     Returns a boolean procedure for any scheme object.

 -- Function: make-method! object generic-method method
     Associates METHOD to the GENERIC-METHOD in the object.  The METHOD overrides any previous association with the GENERIC-METHOD within the object.  Using unmake-method! will restore the object's previous association with the GENERIC-METHOD.  METHOD must be a procedure.

 -- Function: make-predicate! object generic-preciate
     Makes a predicate method associated with the GENERIC-PREDICATE.

 -- Function: unmake-method! object generic-method
     Removes an object's association with a GENERIC-METHOD .

 -- Function: get-method object generic-method
     Returns the object's method associated (if any) with the GENERIC-METHOD.  If no associated method exists an error is flagged.

Examples
--------

     (require 'object)

     (define instantiate (make-generic-method))

     (define (make-instance-object . ancestors)
       (define self (apply make-object
                           (map (lambda (obj) (instantiate obj)) ancestors)))
       (make-method! self instantiate (lambda (self) self))
       self)

     (define who (make-generic-method))
     (define imigrate! (make-generic-method))
     (define emigrate! (make-generic-method))
     (define describe (make-generic-method))
     (define name (make-generic-method))
     (define address (make-generic-method))
     (define members (make-generic-method))

     (define society
       (let ()
         (define self (make-instance-object))
         (define population '())
         (make-method! self imigrate!
                       (lambda (new-person)
                         (if (not (eq? new-person self))
                             (set! population (cons new-person population)))))
         (make-method! self emigrate!
                       (lambda (person)
                         (if (not (eq? person self))
                             (set! population
                                   (comlist:remove-if (lambda (member)
                                                        (eq? member person))
                                                      population)))))
         (make-method! self describe
                       (lambda (self)
                         (map (lambda (person) (describe person)) population)))
         (make-method! self who
                       (lambda (self) (map (lambda (person) (name person))
                                           population)))
         (make-method! self members (lambda (self) population))
         self))

     (define (make-person %name %address)
       (define self (make-instance-object society))
       (make-method! self name (lambda (self) %name))
       (make-method! self address (lambda (self) %address))
       (make-method! self who (lambda (self) (name self)))
       (make-method! self instantiate
                     (lambda (self)
                       (make-person (string-append (name self) "-son-of")
                                    %address)))
       (make-method! self describe
                     (lambda (self) (list (name self) (address self))))
       (imigrate! self)
       self)

Inverter Documentation
......................

Inheritance:

             <inverter>::(<number> <description>)

Generic-methods

             <inverter>::value      => <number>::value
             <inverter>::set-value! => <number>::set-value!
             <inverter>::describe   => <description>::describe
             <inverter>::help
             <inverter>::invert
             <inverter>::inverter?

Number Documention
..................

Inheritance

             <number>::()

Slots

             <number>::<x>

Generic Methods

             <number>::value
             <number>::set-value!

Inverter code
.............

     (require 'object)

     (define value (make-generic-method (lambda (val) val)))
     (define set-value! (make-generic-method))
     (define invert (make-generic-method
                     (lambda (val)
                       (if (number? val)
                           (/ 1 val)
                           (error "Method not supported:" val)))))
     (define noop (make-generic-method))
     (define inverter? (make-generic-predicate))
     (define describe (make-generic-method))
     (define help (make-generic-method))

     (define (make-number x)
       (define self (make-object))
       (make-method! self value (lambda (this) x))
       (make-method! self set-value!
                     (lambda (this new-value) (set! x new-value)))
       self)

     (define (make-description str)
       (define self (make-object))
       (make-method! self describe (lambda (this) str))
       (make-method! self help (lambda (this) "Help not available"))
       self)

     (define (make-inverter)
       (define self (make-object
                     (make-number 1)
                     (make-description "A number which can be inverted")))
       (define <value> (get-method self value))
       (make-method! self invert (lambda (self) (/ 1 (<value> self))))
       (make-predicate! self inverter?)
       (unmake-method! self help)
       (make-method! self help
                     (lambda (self)
                       (display "Inverter Methods:") (newline)
                       (display "  (value inverter) ==> n") (newline)))
       self)

     ;;;; Try it out

     (define invert! (make-generic-method))

     (define x (make-inverter))

     (make-method! x invert! (lambda () (set-value! x (/ 1 (value x)))))

     (value x)                       => 1
     (set-value! x 33)               => undefined
     (invert! x)                     => undefined
     (value x)                       => 1/33

     (unmake-method! x invert!)      => undefined

     (invert! x)                     error-->  ERROR: Method not supported: x

Parameter lists
===============

(require 'parameters)

Arguments to procedures in scheme are distinguished from each other by their position in the procedure call.  This can be confusing when a procedure takes many arguments, many of which are not often used.

A parameter-list is a way of passing named information to a procedure.  Procedures are also defined to set unused parameters to default values, check parameters, and combine parameter lists.

A PARAMETER has the form (parameter-name value1 ...).  This format allows for more than one value per parameter-name.

A PARAMETER-LIST is a list of PARAMETERs, each with a different PARAMETER-NAME.

 -- Function: make-parameter-list parameter-names
     Returns an empty parameter-list with slots for PARAMETER-NAMES.

 -- Function: parameter-list-ref parameter-list parameter-name
     PARAMETER-NAME must name a valid slot of PARAMETER-LIST. parameter-list-ref returns the value of parameter PARAMETER-NAME of PARAMETER-LIST.

 -- Procedure: adjoin-parameters! parameter-list parameter1 ...
     Returns PARAMETER-LIST with PARAMETER1 ... merged in.

 -- Procedure: parameter-list-expand expanders parameter-list
     EXPANDERS is a list of procedures whose order matches the order of the PARAMETER-NAMEs in the call to make-parameter-list which created PARAMETER-LIST.  For each non-false element of EXPANDERS that procedure is mapped over the corresponding parameter value and the returned parameter lists are merged into PARAMETER-LIST.

     This process is repeated until PARAMETER-LIST stops growing.  The value returned from parameter-list-expand is unspecified.

 -- Function: fill-empty-parameters defaults parameter-list
     DEFAULTS is a list of lists whose order matches the order of the PARAMETER-NAMEs in the call to make-parameter-list which created PARAMETER-LIST.  fill-empty-parameters returns a new parameter-list with each empty parameter filled with the corresponding DEFAULT.

 -- Function: check-parameters checks parameter-list
     CHECKS is a list of procedures whose order matches the order of the PARAMETER-NAMEs in the call to make-parameter-list which created PARAMETER-LIST.

     check-parameters returns PARAMETER-LIST if each CHECK of the corresponding PARAMETER-LIST returns non-false.  If some CHECK returns #f an error is signaled.

In the following procedures ARITIES is a list of symbols.  The elements of arities can be:

single
     Requires a single parameter.

optional
     A single parameter or no parameter is acceptable.

boolean
     A single boolean parameter or zero parameters is acceptable.

nary
     Any number of parameters are acceptable.

nary1
     One or more of parameters are acceptable.

 -- Function: parameter-list->arglist positions arities types parameter-list
     Returns PARAMETER-LIST converted to an argument list.  Parameters of ARITY type single and boolean are converted to the single value associated with them.  The other ARITY types are converted to lists of the value(s) of type TYPES.

     POSITIONS is a list of positive integers whose order matches the order of the PARAMETER-NAMEs in the call to make-parameter-list which created PARAMETER-LIST.  The integers specify in which argument position the corresponding parameter should appear.

 -- Function: getopt->parameter-list argc argv optnames arities types aliases
     Returns ARGV converted to a parameter-list.  OPTNAMES are the parameter-names.  ALIASES is a list of lists of strings and elements of OPTNAMES.  Each of these strings which have length of 1 will be treated as a single - option by getopt.  Longer strings will be treated as long-named options (see getopt--).

 -- Function: getopt->arglist argc argv optnames positions arities types defaults checks aliases
     Like getopt->parameter-list, but converts ARGV to an argument-list as specified by OPTNAMES, POSITIONS, ARITIES, TYPES, DEFAULTS, CHECKS, and ALIASES.

These getopt functions can be used with SLIB relational databases.  For an example, see make-command-server.

Priority Queues
===============

(require 'priority-queue)

 -- Function: make-heap pred<?
     Returns a binary heap suitable which can be used for priority queue operations.

 -- Function: heap-length heap
     Returns the number of elements in HEAP.

 -- Procedure: heap-insert! heap item
     Inserts ITEM into HEAP.  ITEM can be inserted multiple times.  The value returned is unspecified.

 -- Function: heap-extract-max! heap
     Returns the item which is larger than all others according to the PRED<? argument to make-heap.  If there are no items in HEAP, an error is signaled.

The algorithm for priority queues was taken from Introduction to Algorithms by T. Cormen, C. Leiserson, R. Rivest.  1989 MIT Press.

Queues
======

(require 'queue)

A queue is a list where elements can be added to both the front and rear, and removed from the front (i.e., they are what are often called dequeues).  A queue may also be used like a stack.

 -- Function: make-queue
     Returns a new, empty queue.

 -- Function: queue? obj
     Returns #t if OBJ is a queue.

 -- Function: queue-empty? q
     Returns #t if the queue Q is empty.

 -- Procedure: queue-push! q datum
     Adds DATUM to the front of queue Q.

 -- Procedure: enquque! q datum
     Adds DATUM to the rear of queue Q.

All of the following functions raise an error if the queue Q is empty.

 -- Function: queue-front q
     Returns the datum at the front of the queue Q.

 -- Function: queue-rear q
     Returns the datum at the rear of the queue Q.

 -- Prcoedure: queue-pop! q
 -- Procedure: dequeue! q
     Both of these procedures remove and return the datum at the front of the queue.  queue-pop! is used to suggest that the queue is being used like a stack.

Records
=======

(require 'record)

The Record package provides a facility for user to define their own record data types.

 -- Function: make-record-type type-name field-names
     Returns a record-type descriptor, a value representing a new data type disjoint from all others.  The TYPE-NAME argument must be a string, but is only used for debugging purposes (such as the printed representation of a record of the new type).  The FIELD-NAMES argument is a list of symbols naming the fields of a record of the new type.  It is an error if the list contains any duplicates.  It is unspecified how record-type descriptors are represented.

 -- Function: record-constructor rtd [field-names]
     Returns a procedure for constructing new members of the type represented by RTD.  The returned procedure accepts exactly as many arguments as there are symbols in the given list, FIELD-NAMES; these are used, in order, as the initial values of those fields in a new record, which is returned by the constructor procedure.  The values of any fields not named in that list are unspecified.  The FIELD-NAMES argument defaults to the list of field names in the call to make-record-type that created the type represented by RTD; if the FIELD-NAMES argument is provided, it is an error if it contains any duplicates or any symbols not in the default list.

 -- Function: record-predicate rtd
     Returns a procedure for testing membership in the type represented by RTD.  The returned procedure accepts exactly one argument and returns a true value if the argument is a member of the indicated record type; it returns a false value otherwise.

 -- Function: record-accessor rtd field-name
     Returns a procedure for reading the value of a particular field of a member of the type represented by RTD.  The returned procedure accepts exactly one argument which must be a record of the appropriate type; it returns the current value of the field named by the symbol FIELD-NAME in that record.  The symbol FIELD-NAME must be a member of the list of field-names in the call to make-record-type that created the type represented by RTD.

 -- Function: record-modifier rtd field-name
     Returns a procedure for writing the value of a particular field of a member of the type represented by RTD.  The returned procedure accepts exactly two arguments: first, a record of the appropriate type, and second, an arbitrary Scheme value; it modifies the field named by the symbol FIELD-NAME in that record to contain the given value. The returned value of the modifier procedure is unspecified.  The symbol FIELD-NAME must be a member of the list of field-names in the call to make-record-type that created the type represented by RTD.

 -- Function: record? obj
     Returns a true value if OBJ is a record of any type and a false value otherwise.  Note that record? may be true of any Scheme value; of course, if it returns true for some particular value, then record-type-descriptor is applicable to that value and returns an appropriate descriptor.

 -- Function: record-type-descriptor record
     Returns a record-type descriptor representing the type of the given record.  That is, for example, if the returned descriptor were passed to record-predicate, the resulting predicate would return a true value when passed the given record.  Note that it is not necessarily the case that the returned descriptor is the one that was passed to record-constructor in the call that created the constructor procedure that created the given record.

 -- Function: record-type-name rtd
     Returns the type-name associated with the type represented by rtd.  The returned value is eqv? to the TYPE-NAME argument given in the call to make-record-type that created the type represented by RTD.

 -- Function: record-type-field-names rtd
     Returns a list of the symbols naming the fields in members of the type represented by RTD.  The returned value is equal? to the field-names argument given in the call to make-record-type that created the type represented by RTD.

Base Table
==========

A base table implementation using Scheme association lists is available as the value of the identifier alist-table after doing:

     (require 'alist-table)

Association list base tables are suitable for small databases and support all Scheme types when temporary and readable/writeable Scheme types when saved.  I hope support for other base table implementations will be added in the future.

This rest of this section documents the interface for a base table implementation from which the Relational Database package constructs a Relational system.  It will be of interest primarily to those wishing to port or write new base-table implementations.

All of these functions are accessed through a single procedure by calling that procedure with the symbol name of the operation.  A procedure will be returned if that operation is supported and #f otherwise.  For example:

     (require 'alist-table)
     (define open-base (alist-table 'make-base))
     make-base       => *a procedure*
     (define foo (alist-table 'foo))
     foo             => #f

 -- Function: make-base filename key-dimension column-types
     Returns a new, open, low-level database (collection of tables) associated with FILENAME.  This returned database has an empty table associated with CATALOG-ID.  The positive integer KEY-DIMENSION is the number of keys composed to make a PRIMARY-KEY for the catalog table.  The list of symbols COLUMN-TYPES describes the types of each column for that table. If the database cannot be created as specified, #f is returned.

     Calling the close-base method on this database and possibly other operations will cause FILENAME to be written to.  If FILENAME is #f a temporary, non-disk based database will be created if such can be supported by the base table implelentation.

 -- Function: open-base filename mutable
     Returns an open low-level database associated with FILENAME.  If MUTABLE? is #t, this database will have methods capable of effecting change to the database.  If MUTABLE? is #f, only methods for inquiring the database will be available.  If the database cannot be opened as specified #f is returned.

     Calling the close-base (and possibly other) method on a MUTABLE?  database will cause FILENAME to be written to.

 -- Function: write-base lldb filename
     Causes the low-level database LLDB to be written to FILENAME.  If the write is successful, also causes LLDB to henceforth be associated with FILENAME.  Calling the close-database (and possibly other) method on LLDB may cause FILENAME to be written to.  If FILENAME is #f this database will be changed to a temporary, non-disk based database if such can be supported by the underlying base table implelentation.  If the operations completed successfully, #t is returned. Otherwise, #f is returned.

 -- Function: sync-base lldb
     Causes the file associated with the low-level database LLDB to be updated to reflect its current state.  If the associated filename is #f, no action is taken and #f is returned.  If this operation completes successfully, #t is returned.  Otherwise, #f is returned.

 -- Function: close-base lldb
     Causes the low-level database LLDB to be written to its associated file (if any).  If the write is successful, subsequent operations to LLDB will signal an error.  If the operations complete successfully, #t is returned.  Otherwise, #f is returned.

 -- Function: make-table lldb key-dimension column-types
     Returns the BASE-ID for a new base table, otherwise returns #f.  The base table can then be opened using (open-table LLDB BASE-ID).  The positive integer KEY-DIMENSION is the number of keys composed to make a PRIMARY-KEY for this table. The list of symbols COLUMN-TYPES describes the types of each column.

 -- Constant: catalog-id
     A constant BASE-ID suitable for passing as a parameter to open-table.  CATALOG-ID will be used as the base table for the system catalog.

 -- Function: open-table lldb base-id key-dimension column-types
     Returns a HANDLE for an existing base table in the low-level database LLDB if that table exists and can be opened in the mode indicated by MUTABLE?, otherwise returns #f.

     As with make-table, the positive integer KEY-DIMENSION is the number of keys composed to make a PRIMARY-KEY for this table. The list of symbols COLUMN-TYPES describes the types of each column.

 -- Function: kill-table lldb base-id key-dimension column-types
     Returns #t if the base table associated with BASE-ID was removed from the low level database LLDB, and #f otherwise.

 -- Function: make-keyifier-1 type
     Returns a procedure which accepts a single argument which must be of type TYPE.  This returned procedure returns an object suitable for being a KEY argument in the functions whose descriptions follow.

     Any 2 arguments of the supported type passed to the returned function which are not equal? must result in returned values which are not equal?.

 -- Function: make-list-keyifier key-dimension types
     The list of symbols TYPES must have at least KEY-DIMENSION elements.  Returns a procedure which accepts a list of length KEY-DIMENSION and whose types must corresopond to the types named by TYPES.  This returned procedure combines the elements of its list argument into an object suitable for being a KEY argument in the functions whose descriptions follow.

     Any 2 lists of supported types (which must at least include symbols and non-negative integers) passed to the returned function which are not equal? must result in returned values which are not equal?.

 -- Function: make-key-extractor key-dimension types column-number
     Returns a procedure which accepts objects produced by application of the result of (make-list-keyifier KEY-DIMENSION TYPES). This procedure returns a KEY which is equal? to the COLUMN-NUMBERth element of the list which was passed to create COMBINED-KEY.  The list TYPES must have at least KEY-DIMENSION elements.

 -- Function: make-key->list key-dimension types
     Returns a procedure which accepts objects produced by application of the result of (make-list-keyifier KEY-DIMENSION TYPES). This procedure returns a list of KEYs which are elementwise equal? to the list which was passed to create COMBINED-KEY.

In the following functions, the KEY argument can always be assumed to be the value returned by a call to a keyify routine.

 -- Function: for-each-key handle procedure
     Calls PROCEDURE once with each KEY in the table opened in HANDLE in an unspecified order.  An unspecified value is returned.

 -- Function: map-key handle procedure
     Returns a list of the values returned by calling PROCEDURE once with each KEY in the table opened in HANDLE in an unspecified order.

 -- Function: ordered-for-each-key handle procedure
     Calls PROCEDURE once with each KEY in the table opened in HANDLE in the natural order for the types of the primary key fields of that table.  An unspecified value is returned.

 -- Function: present? handle key
     Returns a non-#f value if there is a row associated with KEY in the table opened in HANDLE and #f otherwise.

 -- Function: delete handle key
     Removes the row associated with KEY from the table opened in HANDLE.  An unspecified value is returned.

 -- Function: make-getter key-dimension types
     Returns a procedure which takes arguments HANDLE and KEY. This procedure returns a list of the non-primary values of the relation (in the base table opened in HANDLE) whose primary key is KEY if it exists, and #f otherwise.

 -- Function: make-putter key-dimension types
     Returns a procedure which takes arguments HANDLE and KEY and VALUE-LIST.  This procedure associates the primary key KEY with the values in VALUE-LIST (in the base table opened in HANDLE) and returns an unspecified value.

 -- Function: supported-type? symbol
     Returns #t if SYMBOL names a type allowed as a column value by the implementation, and #f otherwise.  At a minimum, an implementation must support the types integer, symbol, string, boolean, and base-id.

 -- Function: supported-key-type? symbol
     Returns #t if SYMBOL names a type allowed as a key value by the implementation, and #f otherwise.  At a minimum, an implementation must support the types integer, and symbol.

integer
     Scheme exact integer.

symbol
     Scheme symbol.

boolean
     #t or #f.

base-id
     Objects suitable for passing as the BASE-ID parameter to open-table.  The value of CATALOG-ID must be an acceptable base-id.

Relational Database
===================

(require 'relational-database)

This package implements a database system inspired by the Relational Model (E. F. Codd, A Relational Model of Data for Large Shared Data Banks).  An SLIB relational database implementation can be created from any Base Table implementation.

Motivations
-----------

Most nontrivial programs contain databases: Makefiles, configure scripts, file backup, calendars, editors, source revision control, CAD systems, display managers, menu GUIs, games, parsers, debuggers, profilers, and even error reporting are all rife with databases.  Coding databases is such a common activity in programming that many may not be aware of how often they do it.

A database often starts as a dispatch in a program.  The author, perhaps because of the need to make the dispatch configurable, the need for correlating dispatch in other routines, or because of changes or growth, devises a data structure to contain the information, a routine for interpreting that data structure, and perhaps routines for augmenting and modifying the stored data.  The dispatch must be converted into this form and tested.

The programmer may need to devise an interactive program for enabling easy examination and modification of the information contained in this database.  Often, in an attempt to foster modularity and avoid delays in release, intermediate file formats for the database information are devised.  It often turns out that users prefer modifying these intermediate files with a text editor to using the interactive program in order to do operations (such as global changes) not forseen by the program's author.

In order to address this need, the concientous software engineer may even provide a scripting language to allow users to make repetitive database changes.  Users will grumble that they need to read a large manual and learn yet another programming language (even if it almost has language "xyz" syntax) in order to do simple configuration.

All of these facilities need to be designed, coded, debugged, documented, and supported; often causing what was very simple in concept to become a major developement project.

This view of databases just outlined is somewhat the reverse of the view of the originators of the Relational Model of database abstraction.  The relational model was devised to unify and allow interoperation of large multi-user databases running on diverse platforms.  A fairly general purpose "Comprehensive Language" for database manipulations is mandated (but not specified) as part of the relational model for databases.

One aspect of the Relational Model of some importance is that the "Comprehensive Language" must be expressible in some form which can be stored in the database.  This frees the programmer from having to make programs data-driven in order to use a database.

This package includes as one of its basic supported types Scheme expressions.  This type allows expressions as defined by the Scheme standards to be stored in the database.  Using slib:eval retrieved expressions can be evaluated (in the top-level environment). Scheme's lambda facilitates closure of environments, modularity, etc. so that procedures (which could not be stored directly most databases) can still be effectively retrieved.  Since slib:eval evaluates expressions in the top-level environment, built-in and user defined procedures can be easily accessed by name.

This package's purpose is to standardize (through a common interface) database creation and usage in Scheme programs.  The relational model's provision for inclusion of language expressions as data as well as the description (in tables, of course) of all of its tables assures that relational databases are powerful enough to assume the roles currently played by thousands of ad-hoc routines and data formats.

Such standardization to a relational-like model brings many benefits:

  * Tables, fields, domains, and types can be dealt with by name in programs.

  * The underlying database implementation can be changed (for performance or other reasons) by changing a single line of code.

  * The formats of tables can be easily extended or changed without altering code.

  * Consistency checks are specified as part of the table descriptions. Changes in checks need only occur in one place.

  * All the configuration information which the developer wishes to group together is easily grouped, without needing to change programs aware of only some of these tables.

  * Generalized report generators, interactive entry programs, and other database utilities can be part of a shared library.  The burden of adding configurability to a program is greatly reduced.

  * Scheme is the "comprehensive language" for these databases.  Scripting for configuration no longer needs to be in a separate language with additional documentation.

  * Scheme's latent types mesh well with the strict typing and logical requirements of the relational model.

  * Portable formats allow easy interchange of data.  The included table descriptions help prevent misinterpretation of format.

Creating and Opening Relational Databases
-----------------------------------------

 -- Function: make-relational-system base-table-implementation

     Returns a procedure implementing a relational database using the BASE-TABLE-IMPLEMENTATION.

     All of the operations of a base table implementation are accessed through a procedure defined by requireing that implementation. Similarly, all of the operations of the relational database implementation are accessed through the procedure returned by make-relational-system.  For instance, a new relational database could be created from the procedure returned by make-relational-system by:

          (require 'alist-table)
          (define relational-alist-system
                  (make-relational-system alist-table))
          (define create-alist-database
                  (relational-alist-system 'create-database))
          (define my-database
                  (create-alist-database "mydata.db"))

What follows are the descriptions of the methods available from relational system returned by a call to make-relational-system.

 -- Function: create-database filename

     Returns an open, nearly empty relational database associated with FILENAME.  The only tables defined are the system catalog and domain table.  Calling the close-database method on this database and possibly other operations will cause FILENAME to be written to.  If FILENAME is #f a temporary, non-disk based database will be created if such can be supported by the underlying base table implelentation.  If the database cannot be created as specified #f is returned.  For the fields and layout of descriptor tables, see Catalog Representation

 -- Function: open-database filename mutable?

     Returns an open relational database associated with FILENAME.  If MUTABLE? is #t, this database will have methods capable of effecting change to the database.  If MUTABLE? is #f, only methods for inquiring the database will be available.  Calling the close-database (and possibly other) method on a MUTABLE? database will cause FILENAME to be written to.  If the database cannot be opened as specified #f is returned.

Relational Database Operations
------------------------------

These are the descriptions of the methods available from an open relational database.  A method is retrieved from a database by calling the database with the symbol name of the operation.  For example:

     (define my-database
             (create-alist-database "mydata.db"))
     (define telephone-table-desc
             ((my-database 'create-table) 'telephone-table-desc))

 -- Function: close-database
     Causes the relational database to be written to its associated file (if any).  If the write is successful, subsequent operations to this database will signal an error.  If the operations completed successfully, #t is returned.  Otherwise, #f is returned.

 -- Function: write-database filename
     Causes the relational database to be written to FILENAME.  If the write is successful, also causes the database to henceforth be associated with FILENAME.  Calling the close-database (and possibly other) method on this database will cause FILENAME to be written to.  If FILENAME is #f this database will be changed to a temporary, non-disk based database if such can be supported by the underlying base table implelentation.  If the operations completed successfully, #t is returned.  Otherwise, #f is returned.

 -- Function: table-exists? table-name
     Returns #t if TABLE-NAME exists in the system catalog, otherwise returns #f.

 -- Function: open-table table-name mutable?
     Returns a methods procedure for an existing relational table in this database if it exists and can be opened in the mode indicated by MUTABLE?, otherwise returns #f.

These methods will be present only in databases which are MUTABLE?.

 -- Function: delete-table table-name
     Removes and returns the TABLE-NAME row from the system catalog if the table or view associated with TABLE-NAME gets removed from the database, and #f otherwise.

 -- Function: create-table table-desc-name
     Returns a methods procedure for a new (open) relational table for describing the columns of a new base table in this database, otherwise returns #f.  For the fields and layout of descriptor tables, see Catalog Representation.

 -- Function: create-table table-name table-desc-name
     Returns a methods procedure for a new (open) relational table with columns as described by TABLE-DESC-NAME, otherwise returns #f.

 -- Function: create-view ??
 -- Function: project-table ??
 -- Function: restrict-table ??
 -- Function: cart-prod-tables ??
     Not yet implemented.

Table Operations
----------------

These are the descriptions of the methods available from an open relational table.  A method is retrieved from a table by calling the table with the symbol name of the operation.  For example:

     (define telephone-table-desc
             ((my-database 'create-table) 'telephone-table-desc))
     (require 'common-list-functions)
     (define ndrp (telephone-table-desc 'row:insert))
     (ndrp '(1 #t name #f string))
     (ndrp '(2 #f telephone
               (lambda (d)
                 (and (string? d) (> (string-length d) 2)
                      (every
                       (lambda (c)
                         (memv c '(#\0 #\1 #\2 #\3 #\4 #\5 #\6 #\7 #\8 #\9
                                       #\+ #\( #\  #\) #\-)))
                       (string->list d))))
               string))

Operations on a single column of a table are retrieved by giving the column name as the second argument to the methods procedure.  For example:

     (define column-ids ((telephone-table-desc 'get* 'column-number)))

Some operations described below require primary key arguments.  Primary keys arguments are denoted KEY1 KEY2 ....  It is an error to call an operation for a table which takes primary key arguments with the wrong number of primary keys for that table.

The term row used below refers to a Scheme list of values (one for each column) in the order specified in the descriptor (table) for this table.  Missing values appear as #f.  Primary keys may not be missing.

 -- Function: get key1 key2 ...
     Returns the value for the specified column of the row associated with primary keys KEY1, KEY2 ... if it exists, or #f otherwise.

 -- Function: get*
     Returns a list of the values for the specified column for all rows in this table.

 -- Function: row:retrieve key1 key2 ...
     Returns the row associated with primary keys KEY1, KEY2 ... if it exists, or #f otherwise.

 -- Function: row:retrieve*
     Returns a list of all rows in this table.

 -- Function: row:remove key1 key2 ...
     Removes and returns the row associated with primary keys KEY1, KEY2 ... if it exists, or #f otherwise.

 -- Function: row:remove*
     Removes and returns a list of all rows in this table.

 -- Function: row:delete key1 key2 ...
     Deletes the row associated with primary keys KEY1, KEY2 ... if it exists.  The value returned is unspecified.

 -- Function: row:delete*
     Deletes all rows in this table.  The value returned is unspecified.  The descriptor table and catalog entry for this table are not affected.

 -- Function: row:update row
     Adds the row, ROW, to this table.  If a row for the primary key(s) specified by ROW already exists in this table, it will be overwritten.  The value returned is unspecified.

 -- Function: row:update* rows
     Adds each row in the list ROWS, to this table.  If a row for the primary key specified by an element of ROWS already exists in this table, it will be overwritten.  The value returned is unspecified.

 -- Function: row:insert row
     Adds the row ROW to this table.  If a row for the primary key(s) specified by ROW already exists in this table an error is signaled.  The value returned is unspecified.

 -- Function: row:insert* rows
     Adds each row in the list ROWS, to this table.  If a row for the primary key specified by an element of ROWS already exists in this table, an error is signaled.  The value returned is unspecified.

 -- Function: for-each-row proc
     Calls PROC with each ROW in this table in the natural ordering for the primary key types.  Real relational programmers would use some least-upper-bound join for every row to get them in order; But we don't have joins yet.

 -- Function: close-table
     Subsequent operations to this table will signal an error.

 -- Constant: column-names
 -- Constant: column-foreigns
 -- Constant: column-domains
 -- Constant: column-types
     Return a list of the column names, foreign-key table names, domain names, or type names respectively for this table.  These 4 methods are different from the others in that the list is returned, rather than a procedure to obtain the list.

 -- Constant: primary-limit
     Returns the number of primary keys fields in the relations in this table.

Catalog Representation
----------------------

Each database (in an implementation) has a system catalog which describes all the user accessible tables in that database (including itself).

The system catalog base table has the following fields.  PRI indicates a primary key for that table.

     PRI table-name
         column-limit            the highest column number
         coltab-name             descriptor table name
         bastab-id               data base table identifier
         user-integrity-rule
         view-procedure          A scheme thunk which, when called,
                                 produces a handle for the view.  coltab
                                 and bastab are specified if and only if
                                 view-procedure is not.

Descriptors for base tables (not views) are tables (pointed to by system catalog).  Descriptor (base) tables have the fields:

     PRI column-number           sequential integers from 1
         primary-key?            boolean TRUE for primary key components
         column-name
         column-integrity-rule
         domain-name

A primary key is any column marked as primary-key? in the corresponding descriptor table.  All the primary-key? columns must have lower column numbers than any non-primary-key? columns. Every table must have at least one primary key.  Primary keys must be sufficient to distinguish all rows from each other in the table.  All of the system defined tables have a single primary key.

This package currently supports tables having from 1 to 4 primary keys if there are non-primary columns, and any (natural) number if all columns are primary keys.  If you need more than 4 primary keys, I would like to hear what you are doing!

A domain is a category describing the allowable values to occur in a column.  It is described by a (base) table with the fields:

     PRI domain-name
         foreign-table
         domain-integrity-rule
         type-id
         type-param

The type-id field value is a symbol.  This symbol may be used by the underlying base table implementation in storing that field.

If the foreign-table field is non-#f then that field names a table from the catalog.  The values for that domain must match a primary key of the table referenced by the TYPE-PARAM (or #f, if allowed).  This package currently does not support composite foreign-keys.

The types for which support is planned are:

         atom
         symbol
         string                  [<length>]
         number                  [<base>]
         money                   <currency>
         date-time
         boolean

         foreign-key             <table-name>
         expression
         virtual                 <expression>

Unresolved Issues
-----------------

Although rdms.scm is not large I found it very difficult to write (six rewrites).  I am not aware of any other examples of a generalized relational system (although there is little new in CS).  I left out several aspects of the Relational model in order to simplify the job. The major features lacking (which might be addressed portably) are views, transaction boundaries, and protection.

Protection needs a model for specifying priveledges.  Given how operations are accessed from handles it should not be difficult to restrict table accesses to those allowed for that user.

The system catalog has a field called view-procedure.  This should allow a purely functional implementation of views.  This will work but is unsatisfying for views resulting from a selection (subset of rows); for whole table operations it will not be possible to reduce the number of keys scanned over when the selection is specified only by an opaque procedure.

Transaction boundaries present the most intriguing area.  Transaction boundaries are actually a feature of the "Comprehensive Language" of the Relational database and not of the database.  Scheme would seem to provide the opportunity for an extremely clean semantics for transaction boundaries since the builtin procedures with side effects are small in number and easily identified.

These side-effect builtin procedures might all be portably redefined to versions which properly handled transactions.  Compiled library routines would need to be recompiled as well.  Many system extensions (delete-file, system, etc.) would also need to be redefined.

There are 2 scope issues that must be resolved for multiprocess transaction boundaries:

Process scope
     The actions captured by a transaction should be only for the process which invoked the start of transaction.  Although standard Scheme does not provide process primitives as such, dynamic-wind would provide a workable hook into process switching for many implementations.

Shared utilities with state
     Some shared utilities have state which should not be part of a transaction.  An example would be calling a pseudo-random number generator.  If the success of a transaction depended on the pseudo-random number and failed, the state of the generator would be set back.  Subsequent calls would keep returning the same number and keep failing.

     Pseudo-random number generators are not reentrant and so would require locks in order to operate properly in a multiprocess environment.  Are all examples of utilities whose state should not part of transactions also non-reentrant?  If so, perhaps suspending transaction capture for the duration of locks would fix it.

Database Utilities
------------------

(require 'database-utilities)

This enhancement wraps a utility layer on relational-database which provides:

  * Automatic loading of the appropriate base-table package when opening a database.

  * Automatic execution of initialization commands stored in database.

  * Transparent execution of database commands stored in *commands* table in database.

Also included are utilities which provide:

  * Data definition from Scheme lists and

  * Report generation

for any SLIB relational database.

 -- Function: create-database filename base-table-type
     Returns an open, nearly empty enhanced (with *commands* table) relational database (with base-table type BASE-TABLE-TYPE) associated with FILENAME.

 -- Function: open-database filename
 -- Function: open-database filename base-table-type
     Returns an open enchanced relational database associated with FILENAME.  The database will be opened with base-table type BASE-TABLE-TYPE) if supplied.  If BASE-TABLE-TYPE is not supplied, open-database will attempt to deduce the correct base-table-type.  If the database can not be opened or if it lacks the *commands* table, #f is returned.

 -- Function: open-database! filename
 -- Function: open-database! filename base-table-type
     Returns mutable open enchanced relational database ...

The table *commands* in an enhanced relational-database has the fields (with domains):

     PRI name        symbol
         parameters  parameter-list
         procedure   expression
         documentation string

The parameters field is a foreign key (domain parameter-list) of the *catalog-data* table and should have the value of a table described by *parameter-columns*.  This parameter-list table describes the arguments suitable for passing to the associated command.  The intent of this table is to be of a form such that different user-interfaces (for instance, pull-down menus or plain-text queries) can operate from the same table.  A parameter-list table has the following fields:

     PRI index       uint
         name        symbol
         arity       parameter-arity
         domain      domain
         default     expression
         documentation string

The arity field can take the values:

single
     Requires a single parameter of the specified domain.

optional
     A single parameter of the specified domain or zero parameters is acceptable.

boolean
     A single boolean parameter or zero parameters (in which case #f is substituted) is acceptable.

nary
     Any number of parameters of the specified domain are acceptable.  The argument passed to the command function is always a list of the parameters.

nary1
     One or more of parameters of the specified domain are acceptable.  The argument passed to the command function is always a list of the parameters.

The domain field specifies the domain which a parameter or parameters in the indexth field must satisfy.

The default field is an expression whose value is either #f or a procedure of no arguments which returns a parameter or parameter list as appropriate.  If the expression's value is #f then no default is appropriate for this parameter.  Note that since the default procedure is called every time a default parameter is needed for this column, sticky defaults can be implemented using shared state with the domain-integrity-rule.

Invoking Commands
.................

When an enhanced relational-database is called with a symbol which matches a NAME in the *commands* table, the associated procedure expression is evaluated and applied to the enhanced relational-database.  A procedure should then be returned which the user can invoke on (optional) arguments.

The command *initialize* is special.  If present in the *commands* table, open-database or open-database! will return the value of the *initialize* command.  Notice that arbitrary code can be run when the *initialize* procedure is automatically applied to the enhanced relational-database.

Note also that if you wish to shadow or hide from the user relational-database methods described in Relational Database Operations, this can be done by a dispatch in the closure returned by the *initialize* expression rather than by entries in the *commands* table if it is desired that the underlying methods remain accessible to code in the *commands* table.

 -- Function: make-command-server rdb table-name
     Returns a procedure of 2 arguments, a (symbol) command and a call-back procedure.  When this returned procedure is called, it looks up COMMAND in table TABLE-NAME and calls the call-back procedure with arguments:

     command
          The COMMAND

     command-value
          The result of evaluating the expression in the PROCEDURE field of TABLE-NAME and calling it with RDB.

     parameter-name
          A list of the official name of each parameter.  Corresponds to the name field of the COMMAND's parameter-table.

     positions
          A list of the positive integer index of each parameter.  Corresponds to the index field of the COMMAND's parameter-table.

     arities
          A list of the arities of each parameter.  Corresponds to the arity field of the COMMAND's parameter-table.  For a description of arity see table above.

     defaults
          A list of the defaults for each parameter.  Corresponds to the defaults field of the COMMAND's parameter-table.

     domain-integrity-rules
          A list of procedures (one for each parameter) which tests whether a value for a parameter is acceptable for that parameter.  The procedure should be called with each datum in the list for nary arity parameters.

     aliases
          A list of lists of (alias, parameter-name).  There can be more than one alias per PARAMETER-NAME.

For information about parameters, see Parameter lists.  Here is an example of setting up a command with arguments and parsing those arguments from a getopt style argument list (see Getopt).

     (require 'database-utilities)
     (require 'parameters)
     (require 'getopt)

     (define my-rdb (create-database #f 'alist-table))

     (define-tables my-rdb
       '(foo-params
         *parameter-columns*
         *parameter-columns*
         ((1 first-argument single string "hithere" "first argument")
          (2 flag boolean boolean #f "a flag")))
       '(foo-pnames
         ((name string))
         ((parameter-index uint))
         (("l" 1)
          ("a" 2)))
       '(my-commands
         ((name symbol))
         ((parameters parameter-list)
          (parameter-names parameter-name-translation)
          (procedure expression)
          (documentation string))
         ((foo
           foo-params
           foo-pnames
           (lambda (rdb) (lambda (foo aflag) (print foo aflag)))
           "test command arguments"))))

     (define (dbutil:serve-command-line rdb command-table
                                        command argc argv)
       (set! argv (if (vector? argv) (vector->list argv) argv))
       ((make-command-server rdb command-table)
        command
        (lambda (comname comval options positions
                         arities types defaults dirs aliases)
          (apply comval (getopt->arglist argc argv options positions
                                         arities types defaults dirs aliases)))))

     (define (test)
       (set! *optind* 1)
       (dbutil:serve-command-line
        my-rdb 'my-commands 'foo 4 '("dummy" "-l" "foo" "-a")))
     (test)
     -|
     "foo" #t

Some commands are defined in all extended relational-databases.  The are called just like Relational Database Operations.

 -- Function: add-domain domain-row
     Adds DOMAIN-ROW to the domains table if there is no row in the domains table associated with key (car DOMAIN-ROW) and returns #t.  Otherwise returns #f.

     For the fields and layout of the domain table, see Catalog Representation

 -- Function: delete-domain domain-name
     Removes and returns the DOMAIN-NAME row from the domains table.

 -- Function: domain-checker domain
     Returns a procedure to check an argument for conformance to domain DOMAIN.

Defining Tables
---------------

 -- Procedure: define-tables rdb spec-0 ...
     Adds tables as specified in SPEC-0 ... to the open relational-database RDB.  Each SPEC has the form:

          (<name> <descriptor-name> <descriptor-name> <rows>)

     or

          (<name> <primary-key-fields> <other-fields> <rows>)

     where <name> is the table name, <descriptor-name> is the symbol name of a descriptor table, <primary-key-fields> and <other-fields> describe the primary keys and other fields respectively, and <rows> is a list of data rows to be added to the table.

     <primary-key-fields> and <other-fields> are lists of field descriptors of the form:

          (<column-name> <domain>)

     or

          (<column-name> <domain> <column-integrity-rule>)

     where <column-name> is the column name, <domain> is the domain of the column, and <column-integrity-rule> is an expression whose value is a procedure of one argument (and returns non-#f to signal an error).

     If <domain> is not a defined domain name and it matches the name of this table or an already defined (in one of SPEC-0 ...) single key field table, a foriegn-key domain will be created for it.

 -- Procedure: create-report rdb destination report-name table
 -- Procedure: create-report rdb destination report-name
     The symbol REPORT-NAME must be primary key in the table named *reports* in the relational database RDB. DESTINATION is a port, string, or symbol.  If DESTINATION is a:

     port
          The table is created as ascii text and written to that port.

     string
          The table is created as ascii text and written to the file named by DESTINATION.

     symbol
          DESTINATION is the primary key for a row in the table named *printers*.

     Each row in the table *reports* has the fields:

     name
          The report name.

     default-table
          The table to report on if none is specified.

     header
     footer
          A format string.  At the beginning and end of each page respectively, format is called with this string and the (list of) column-names of this table.

     reporter
          A format string.  For each row in the table, format is called with this string and the row.

     minimum-break
          The minimum number of lines into which the report lines for a row can be broken.  Use 0 if a row's lines should not be broken over page boundaries.

     Each row in the table *printers* has the fields:

     name
          The printer name.

     print-procedure
          The procedure to call to actually print.

     The report is prepared as follows:

       * Format (see Format) is called with the header field and the (list of) column-names of the table.

       * Format is called with the reporter field and (on successive calls) each record in the natural order for the table.  A count is kept of the number of newlines output by format.  When the number of newlines to be output exceeds the number of lines per page, the set of lines will be broken if there are more than minimum-break left on this page and the number of lines for this row is larger or equal to twice minimum-break.

       * Format is called with the footer field and the (list of) column-names of the table.  The footer field should not output a newline.

       * A new page is output.

       * This entire process repeats until all the rows are output.

The following example shows a new database with the name of foo.db being created with tables describing processor families and processor/os/compiler combinations.

The database command define-tables is defined to call define-tables with its arguments.  The database is also configured to print Welcome when the database is opened.  The database is then closed and reopened.

     (require 'database-utilities)
     (define my-rdb (create-database "foo.db" 'alist-table))

     (define-tables my-rdb
       '(*commands*
         ((name symbol))
         ((parameters parameter-list)
          (procedure expression)
          (documentation string))
         ((define-tables
           no-parameters
           no-parameter-names
           (lambda (rdb) (lambda specs (apply define-tables rdb specs)))
           "Create or Augment tables from list of specs")
          (*initialize*
           no-parameters
           no-parameter-names
           (lambda (rdb) (display "Welcome") (newline) rdb)
           "Print Welcome"))))

     ((my-rdb 'define-tables)
      '(processor-family
        ((family    atom))
        ((also-ran  processor-family))
        ((m68000           #f)
         (m68030           m68000)
         (i386             8086)
         (8086             #f)
         (powerpc          #f)))

      '(platform
        ((name      symbol))
        ((processor processor-family)
         (os        symbol)
         (compiler  symbol))
        ((aix              powerpc aix     -)
         (amiga-dice-c     m68000  amiga   dice-c)
         (amiga-aztec      m68000  amiga   aztec)
         (amiga-sas/c-5.10 m68000  amiga   sas/c)
         (atari-st-gcc     m68000  atari   gcc)
         (atari-st-turbo-c m68000  atari   turbo-c)
         (borland-c-3.1    8086    ms-dos  borland-c)
         (djgpp            i386    ms-dos  gcc)
         (linux            i386    linux   gcc)
         (microsoft-c      8086    ms-dos  microsoft-c)
         (os/2-emx         i386    os/2    gcc)
         (turbo-c-2        8086    ms-dos  turbo-c)
         (watcom-9.0       i386    ms-dos  watcom))))

     ((my-rdb 'close-database))

     (set! my-rdb (open-database "foo.db" 'alist-table))
     -|
     Welcome

Red-Black Trees
===============

(require 'red-black-tree)

This is an implementation of Red-Black trees in Scheme.

 -- Function: make-rb-tree left-rotation-field-maintainer right-rotation-field-maintainer insertion-field-maintainer deletion-field-maintainer prior?
     Makes an empty Red-Black tree based on the arguments:

     left-rotation-field-maintainer

     right-rotation-field-maintainer
          Invoked in rotations to maintain augmented fields.  Args are X and Y. If you have no augmented fields that depend explicitly on the structure of the tree, make these null.

     insertion-field-maintainer
          Invoked in insertion to maintain fields.  Invoked once, on node inserted after insertion is performed, but before rotations are performed to balance tree.  May also be invoked in one case of deletion.

     deletion-field-maintainer
          Invoked in deletion to maintain fields.  Invoked once, on node deleted after deletion is performed, but before rotations are performed to balance the tree.  May be invoked on non-garbage nodes during deletion, where node is spliced out of one place and into another.  The tree is always guaranteed connected from parent up.

     prior?
          PRIOR? should be a binary predicate used for totally ordering the data fields of nodes.  The name PRIOR? is just a mnemonic aid; it means that if the predicate is successful the first arg should go to the left of the second arg, where left is in tree fields.

 -- Procedure: rb-delete! tree node
     Deletes NODE from TREE.  The node that is actually deleted may not be the one passed in, so if a resource is being maintained, what should be put back on the freelist is the NODE returned by this procedure.

 -- Function: rb-node-successor node
 -- Function: rb-node-predecessor node
     Return the successor and predecessor (as determined by the PRIOR? argument to make-rb-tree) from the tree of which NODE is a member.

 -- Function: rb-node-maximum node
 -- Function: rb-node-minimum node
     Return the minimum and maximum nodes in the tree of which NODE is a member.

 -- Function: rb-tree-maximum tree
 -- Function: rb-tree-minimum tree
     Return the minimum and maximum nodes in TREE.

 -- Procedure: rb-insert! tree node
     Inserts NODE in TREE.  The value returned is unspecified.

 -- Function: make-rb-node data
     Makes a node (suitable for insertion with rb-insert!) with datum DATA.

Structures
==========

(require 'struct) (uses defmacros)

defmacros which implement records from the book Essentials of Programming Languages by Daniel P. Friedman, M. Wand and C.T. Haynes.  Copyright 1992 Jeff Alexander, Shinnder Lee, and Lewis Patterson

Matthew McDonald <mafm@cs.uwa.edu.au> added field setters.

 -- Macro: define-record tag (var1 var2 ...)
     Defines several functions pertaining to record-name TAG: MAKE-TAG, TAG?, TAG-VAR1, and SET-TAG-VAR1!.

 -- Macro: variant-case exp (tag (var1 var2 ...) body) ...
     executes the following for the matching clause:

          ((lambda (VAR1 VAR ...) BODY)
             (TAG->VAR1 EXP)
             (TAG->VAR2 EXP) ...)

Macros
******

Defmacro
========

Defmacros are supported by all implementations.

 -- Function: gentemp
     Returns a new (interned) symbol each time it is called.  The symbol names are implementation-dependent

          (gentemp) => scm:G0
          (gentemp) => scm:G1

 -- Function: defmacro:eval e
     Returns the slib:eval of expanding all defmacros in scheme expression E.

 -- Function: defmacro:load filename
     FILENAME should be a string.  If filename names an existing file, the defmacro:load procedure reads Scheme source code expressions and definitions from the file and evaluates them sequentially.  These source code expressions and definitions may contain defmacro definitions.  The macro:load procedure does not affect the values returned by current-input-port and current-output-port.

 -- Function: defmacro? sym
     Returns #t if SYM has been defined by defmacro, #f otherwise.

 -- Function: macroexpand-1 form
 -- Function: macroexpand form
     If FORM is a macro call, macroexpand-1 will expand the macro call once and return it.  A FORM is considered to be a macro call only if it is a cons whose car is a symbol for which a defmacr has been defined.

     macroexpand is similar to macroexpand-1, but repeatedly expands FORM until it is no longer a macro call.

 -- Macro: defmacro name lambda-list form ...
     When encountered by defmacro:eval, defmacro:macroexpand*, or defmacro:load defines a new macro which will henceforth be expanded when encountered by defmacro:eval, defmacro:macroexpand*, or defmacro:load.

Defmacroexpand
--------------

(require 'defmacroexpand)

 -- Function: defmacro:expand* e
     Returns the result of expanding all defmacros in scheme expression E.

R4RS Macros
===========

(require 'macro) is the appropriate call if you want R4RS high-level macros but don't care about the low level implementation.  If an SLIB R4RS macro implementation is already loaded it will be used. Otherwise, one of the R4RS macros implemetations is loaded.

The SLIB R4RS macro implementations support the following uniform interface:

 -- Function: macro:expand sexpression
     Takes an R4RS expression, macro-expands it, and returns the result of the macro expansion.

 -- Function: macro:eval sexpression
     Takes an R4RS expression, macro-expands it, evals the result of the macro expansion, and returns the result of the evaluation.

 -- Procedure: macro:load filename
     FILENAME should be a string.  If filename names an existing file, the macro:load procedure reads Scheme source code expressions and definitions from the file and evaluates them sequentially.  These source code expressions and definitions may contain macro definitions.  The macro:load procedure does not affect the values returned by current-input-port and current-output-port.

Macro by Example
================

(require 'macro-by-example)

A vanilla implementation of Macro by Example (Eugene Kohlbecker, R4RS) by Dorai Sitaram, (dorai@cs.rice.edu) using defmacro.

  * generating hygienic global define-syntax Macro-by-Example macros cheaply.

  * can define macros which use ....

  * needn't worry about a lexical variable in a macro definition clashing with a variable from the macro use context

  * don't suffer the overhead of redefining the repl if defmacro natively supported (most implementations)

Caveat
------

These macros are not referentially transparent (see Macros (Revised(4) Scheme)).  Lexically scoped macros (i.e., let-syntax and letrec-syntax) are not supported.  In any case, the problem of referential transparency gains poignancy only when let-syntax and letrec-syntax are used.  So you will not be courting large-scale disaster unless you're using system-function names as local variables with unintuitive bindings that the macro can't use.  However, if you must have the full r4rs macro functionality, look to the more featureful (but also more expensive) versions of syntax-rules available in slib Macros That Work, Syntactic Closures, and Syntax-Case Macros.

 -- Macro: define-syntax keyword transformer-spec
     The KEYWORD is an identifier, and the TRANSFORMER-SPEC should be an instance of syntax-rules.

     The top-level syntactic environment is extended by binding the KEYWORD to the specified transformer.

          (define-syntax let*
            (syntax-rules ()
              ((let* () body1 body2 ...)
               (let () body1 body2 ...))
              ((let* ((name1 val1) (name2 val2) ...)
                 body1 body2 ...)
               (let ((name1 val1))
                 (let* (( name2 val2) ...)
                   body1 body2 ...)))))

 -- Macro: syntax-rules literals syntax-rule ...
     LITERALS is a list of identifiers, and each SYNTAX-RULE should be of the form

     (PATTERN TEMPLATE)

     where the PATTERN and  TEMPLATE are as in the grammar above.

     An instance of syntax-rules produces a new macro transformer by specifying a sequence of hygienic rewrite rules.  A use of a macro whose keyword is associated with a transformer specified by syntax-rules is matched against the patterns contained in the SYNTAX-RULEs, beginning with the leftmost SYNTAX-RULE. When a match is found, the macro use is trancribed hygienically according to the template.

     Each pattern begins with the keyword for the macro.  This keyword is not involved in the matching and is not considered a pattern variable or literal identifier.

Macros That Work
================

(require 'macros-that-work)

Macros That Work differs from the other R4RS macro implementations in that it does not expand derived expression types to primitive expression types.

 -- Function: macro:expand expression
 -- Function: macwork:expand expression
     Takes an R4RS expression, macro-expands it, and returns the result of the macro expansion.

 -- Function: macro:eval expression
 -- Function: macwork:eval expression
     macro:eval returns the value of EXPRESSION in the current top level environment.  EXPRESSION can contain macro definitions. Side effects of EXPRESSION will affect the top level environment.

 -- Procedure: macro:load filename
 -- Procedure: macwork:load filename
     FILENAME should be a string.  If filename names an existing file, the macro:load procedure reads Scheme source code expressions and definitions from the file and evaluates them sequentially.  These source code expressions and definitions may contain macro definitions.  The macro:load procedure does not affect the values returned by current-input-port and current-output-port.

References:

The Revised^4 Report on the Algorithmic Language Scheme Clinger and Rees [editors].  To appear in LISP Pointers.  Also available as a technical report from the University of Oregon, MIT AI Lab, and Cornell.

Macros That Work.  Clinger and Rees.  POPL '91.

The supported syntax differs from the R4RS in that vectors are allowed as patterns and as templates and are not allowed as pattern or template data.

     transformer spec  ==>  (syntax-rules literals rules)

     rules  ==>  ()
              |  (rule . rules)

     rule  ==>  (pattern template)

     pattern  ==>  pattern_var      ; a symbol not in literals
                |  symbol           ; a symbol in literals
                |  ()
                |  (pattern . pattern)
                |  (ellipsis_pattern)
                |  #(pattern*)                     ; extends R4RS
                |  #(pattern* ellipsis_pattern)    ; extends R4RS
                |  pattern_datum

     template  ==>  pattern_var
                 |  symbol
                 |  ()
                 |  (template2 . template2)
                 |  #(template*)                   ; extends R4RS
                 |  pattern_datum

     template2  ==>  template
                  |  ellipsis_template

     pattern_datum  ==>  string                    ; no vector
                      |  character
                      |  boolean
                      |  number

     ellipsis_pattern  ==> pattern ...

     ellipsis_template  ==>  template ...

     pattern_var  ==>  symbol   ; not in literals

     literals  ==>  ()
                 |  (symbol . literals)

Definitions
-----------

Scope of an ellipsis
     Within a pattern or template, the scope of an ellipsis (...) is the pattern or template that appears to its left.

Rank of a pattern variable
     The rank of a pattern variable is the number of ellipses within whose scope it appears in the pattern.

Rank of a subtemplate
     The rank of a subtemplate is the number of ellipses within whose scope it appears in the template.

Template rank of an occurrence of a pattern variable
     The template rank of an occurrence of a pattern variable within a template is the rank of that occurrence, viewed as a subtemplate.

Variables bound by a pattern
     The variables bound by a pattern are the pattern variables that appear within it.

Referenced variables of a subtemplate
     The referenced variables of a subtemplate are the pattern variables that appear within it.

Variables opened by an ellipsis template
     The variables opened by an ellipsis template are the referenced pattern variables whose rank is greater than the rank of the ellipsis template.

Restrictions
------------

No pattern variable appears more than once within a pattern.

For every occurrence of a pattern variable within a template, the template rank of the occurrence must be greater than or equal to the pattern variable's rank.

Every ellipsis template must open at least one variable.

For every ellipsis template, the variables opened by an ellipsis template must all be bound to sequences of the same length.

The compiled form of a RULE is

     rule  ==>  (pattern template inserted)

     pattern  ==>  pattern_var
                |  symbol
                |  ()
                |  (pattern . pattern)
                |  ellipsis_pattern
                |  #(pattern)
                |  pattern_datum

     template  ==>  pattern_var
                 |  symbol
                 |  ()
                 |  (template2 . template2)
                 |  #(pattern)
                 |  pattern_datum

     template2  ==>  template
                  |  ellipsis_template

     pattern_datum  ==>  string
                      |  character
                      |  boolean
                      |  number

     pattern_var  ==>  #(V symbol rank)

     ellipsis_pattern  ==>  #(E pattern pattern_vars)

     ellipsis_template  ==>  #(E template pattern_vars)

     inserted  ==>  ()
                 |  (symbol . inserted)

     pattern_vars  ==>  ()
                     |  (pattern_var . pattern_vars)

     rank  ==>  exact non-negative integer

where V and E are unforgeable values.

The pattern variables associated with an ellipsis pattern are the variables bound by the pattern, and the pattern variables associated with an ellipsis template are the variables opened by the ellipsis template.

If the template contains a big chunk that contains no pattern variables or inserted identifiers, then the big chunk will be copied unnecessarily.  That shouldn't matter very often.

Syntactic Closures
==================

(require 'syntactic-closures)

 -- Function: macro:expand expression
 -- Function: synclo:expand expression
     Returns scheme code with the macros and derived expression types of EXPRESSION expanded to primitive expression types.

 -- Function: macro:eval expression
 -- Function: synclo:eval expression
     macro:eval returns the value of EXPRESSION in the current top level environment.  EXPRESSION can contain macro definitions. Side effects of EXPRESSION will affect the top level environment.

 -- Procedure: macro:load filename
 -- Procedure: synclo:load filename
     FILENAME should be a string.  If filename names an existing file, the macro:load procedure reads Scheme source code expressions and definitions from the file and evaluates them sequentially.  These source code expressions and definitions may contain macro definitions. The macro:load procedure does not affect the values returned by current-input-port and current-output-port.

Syntactic Closure Macro Facility
--------------------------------

A Syntactic Closures Macro Facility
by Chris Hanson
9 November 1991

This document describes syntactic closures, a low-level macro facility for the Scheme programming language.  The facility is an alternative to the low-level macro facility described in the Revised^4 Report on Scheme. This document is an addendum to that report.

The syntactic closures facility extends the BNF rule for TRANSFORMER SPEC to allow a new keyword that introduces a low-level macro transformer:

     TRANSFORMER SPEC := (transformer EXPRESSION)

Additionally, the following procedures are added:

     make-syntactic-closure
     capture-syntactic-environment
     identifier?
     identifier=?

The description of the facility is divided into three parts.  The first part defines basic terminology.  The second part describes how macro transformers are defined.  The third part describes the use of identifiers, which extend the syntactic closure mechanism to be compatible with syntax-rules.

Terminology
...........

This section defines the concepts and data types used by the syntactic closures facility.

  * Forms are the syntactic entities out of which programs are recursively constructed.  A form is any expression, any definition, any syntactic keyword, or any syntactic closure.  The variable name that appears in a set! special form is also a form.  Examples of forms:

          17
          #t
          car
          (+ x 4)
          (lambda (x) x)
          (define pi 3.14159)
          if
          define

  * An alias is an alternate name for a given symbol.  It can appear anywhere in a form that the symbol could be used, and when quoted it is replaced by the symbol; however, it does not satisfy the predicate symbol?.  Macro transformers rarely distinguish symbols from aliases, referring to both as identifiers.

  * A syntactic environment maps identifiers to their meanings.  More precisely, it determines whether an identifier is a syntactic keyword or a variable.  If it is a keyword, the meaning is an interpretation for the form in which that keyword appears.  If it is a variable, the meaning identifies which binding of that variable is referenced.  In short, syntactic environments contain all of the contextual information necessary for interpreting the meaning of a particular form.

  * A syntactic closure consists of a form, a syntactic environment, and a list of identifiers.  All identifiers in the form take their meaning from the syntactic environment, except those in the given list.  The identifiers in the list are to have their meanings determined later.  A syntactic closure may be used in any context in which its form could have been used.  Since a syntactic closure is also a form, it may not be used in contexts where a form would be illegal. For example, a form may not appear as a clause in the cond special form. A syntactic closure appearing in a quoted structure is replaced by its form.

Transformer Definition
......................

This section describes the transformer special form and the procedures make-syntactic-closure and capture-syntactic-environment.

 -- Syntax: transformer expression

     Syntax: It is an error if this syntax occurs except as a TRANSFORMER SPEC.

     Semantics: The EXPRESSION is evaluated in the standard transformer environment to yield a macro transformer as described below.  This macro transformer is bound to a macro keyword by the special form in which the transformer expression appears (for example, let-syntax).

     A macro transformer is a procedure that takes two arguments, a form and a syntactic environment, and returns a new form.  The first argument, the input form, is the form in which the macro keyword occurred.  The second argument, the usage environment, is the syntactic environment in which the input form occurred.  The result of the transformer, the output form, is automatically closed in the transformer environment, which is the syntactic environment in which the transformer expression occurred.

     For example, here is a definition of a push macro using syntax-rules:

          (define-syntax  push
            (syntax-rules ()
              ((push item list)
               (set! list (cons item list)))))

     Here is an equivalent definition using transformer:

          (define-syntax push
            (transformer
             (lambda (exp env)
               (let ((item
                      (make-syntactic-closure env '() (cadr exp)))
                     (list
                      (make-syntactic-closure env '() (caddr exp))))
                 `(set! ,list (cons ,item ,list))))))

     In this example, the identifiers set! and cons are closed in the transformer environment, and thus will not be affected by the meanings of those identifiers in the usage environment env.

     Some macros may be non-hygienic by design.  For example, the following defines a loop macro that implicitly binds exit to an escape procedure.  The binding of exit is intended to capture free references to exit in the body of the loop, so exit must be left free when the body is closed:

          (define-syntax loop
            (transformer
             (lambda (exp env)
               (let ((body (cdr exp)))
                 `(call-with-current-continuation
                   (lambda (exit)
                     (let f ()
                       ,@(map (lambda  (exp)
                                 (make-syntactic-closure env '(exit)
                                                         exp))
                               body)
                       (f))))))))

     To assign meanings to the identifiers in a form, use make-syntactic-closure to close the form in a syntactic environment.

 -- Function: make-syntactic-closure environment free-names form

     ENVIRONMENT must be a syntactic environment, FREE-NAMES must be a list of identifiers, and FORM must be a form. make-syntactic-closure constructs and returns a syntactic closure of FORM in ENVIRONMENT, which can be used anywhere that FORM could have been used.  All the identifiers used in FORM, except those explicitly excepted by FREE-NAMES, obtain their meanings from ENVIRONMENT.

     Here is an example where FREE-NAMES is something other than the empty list.  It is instructive to compare the use of FREE-NAMES in this example with its use in the loop example above: the examples are similar except for the source of the identifier being left free.

          (define-syntax let1
            (transformer
             (lambda (exp env)
               (let ((id (cadr exp))
                     (init (caddr exp))
                     (exp (cadddr exp)))
                 `((lambda (,id)
                     ,(make-syntactic-closure env (list id) exp))
                   ,(make-syntactic-closure env '() init))))))

     let1 is a simplified version of let that only binds a single identifier, and whose body consists of a single expression.  When the body expression is syntactically closed in its original syntactic environment, the identifier that is to be bound by let1 must be left free, so that it can be properly captured by the lambda in the output form.

     To obtain a syntactic environment other than the usage environment, use capture-syntactic-environment.

 -- Function: capture-syntactic-environment procedure

     capture-syntactic-environment returns a form that will, when transformed, call PROCEDURE on the current syntactic environment. PROCEDURE should compute and return a new form to be transformed, in that same syntactic environment, in place of the form.

     An example will make this clear.  Suppose we wanted to define a simple loop-until keyword equivalent to

          (define-syntax loop-until
            (syntax-rules ()
              ((loop-until id init test return step)
               (letrec ((loop
                         (lambda (id)
                           (if test return (loop step)))))
                 (loop init)))))

     The following attempt at defining loop-until has a subtle bug:

          (define-syntax loop-until
            (transformer
             (lambda (exp env)
               (let ((id (cadr exp))
                     (init (caddr exp))
                     (test (cadddr exp))
                     (return (cadddr (cdr exp)))
                     (step (cadddr (cddr exp)))
                     (close
                      (lambda (exp free)
                        (make-syntactic-closure env free exp))))
                 `(letrec ((loop
                            (lambda (,id)
                              (if ,(close test (list id))
                                  ,(close return (list id))
                                  (loop ,(close step (list id)))))))
                    (loop ,(close init '())))))))

     This definition appears to take all of the proper precautions to prevent unintended captures.  It carefully closes the subexpressions in their original syntactic environment and it leaves the id identifier free in the test, return, and step expressions, so that it will be captured by the binding introduced by the lambda expression.  Unfortunately it uses the identifiers if and loop within that lambda expression, so if the user of loop-until just happens to use, say, if for the identifier, it will be inadvertently captured.

     The syntactic environment that if and loop want to be exposed to is the one just outside the lambda expression: before the user's identifier is added to the syntactic environment, but after the identifier loop has been added. capture-syntactic-environment captures exactly that environment as follows:

          (define-syntax loop-until
            (transformer
             (lambda (exp env)
               (let ((id (cadr exp))
                     (init (caddr exp))
                     (test (cadddr exp))
                     (return (cadddr (cdr exp)))
                     (step (cadddr (cddr exp)))
                     (close
                      (lambda (exp free)
                        (make-syntactic-closure env free exp))))
                 `(letrec ((loop
                            ,(capture-syntactic-environment
                              (lambda (env)
                                `(lambda (,id)
                                   (,(make-syntactic-closure env '() `if)
                                    ,(close test (list id))
                                    ,(close return (list id))
                                    (,(make-syntactic-closure env '()
                                                              `loop)
                                     ,(close step (list id)))))))))
                    (loop ,(close init '())))))))

     In this case, having captured the desired syntactic environment, it is convenient to construct syntactic closures of the identifiers if and the loop and use them in the body of the lambda.

     A common use of capture-syntactic-environment is to get the transformer environment of a macro transformer:

          (transformer
           (lambda (exp env)
             (capture-syntactic-environment
              (lambda (transformer-env)
                ...))))

Identifiers
...........

This section describes the procedures that create and manipulate identifiers.  Previous syntactic closure proposals did not have an identifier data type -- they just used symbols.  The identifier data type extends the syntactic closures facility to be compatible with the high-level syntax-rules facility.

As discussed earlier, an identifier is either a symbol or an alias.  An alias is implemented as a syntactic closure whose form is an identifier:

     (make-syntactic-closure env '() 'a)
        => an alias

Aliases are implemented as syntactic closures because they behave just like syntactic closures most of the time.  The difference is that an alias may be bound to a new value (for example by lambda or let-syntax); other syntactic closures may not be used this way. If an alias is bound, then within the scope of that binding it is looked up in the syntactic environment just like any other identifier.

Aliases are used in the implementation of the high-level facility syntax-rules.  A macro transformer created by syntax-rules uses a template to generate its output form, substituting subforms of the input form into the template.  In a syntactic closures implementation, all of the symbols in the template are replaced by aliases closed in the transformer environment, while the output form itself is closed in the usage environment.  This guarantees that the macro transformation is hygienic, without requiring the transformer to know the syntactic roles of the substituted input subforms.

 -- Function: identifier? object
     Returns #t if OBJECT is an identifier, otherwise returns #f.  Examples:

          (identifier? 'a)
             => #t
          (identifier? (make-syntactic-closure env '() 'a))
             => #t
          (identifier? "a")
             => #f
          (identifier? #\a)
             => #f
          (identifier? 97)
             => #f
          (identifier? #f)
             => #f
          (identifier? '(a))
             => #f
          (identifier? '#(a))
             => #f

     The predicate eq? is used to determine if two identifers are ``the same''.  Thus eq? can be used to compare identifiers exactly as it would be used to compare symbols.  Often, though, it is useful to know whether two identifiers ``mean the same thing''.  For example, the cond macro uses the symbol else to identify the final clause in the conditional.  A macro transformer for cond cannot just look for the symbol else, because the cond form might be the output of another macro transformer that replaced the symbol else with an alias.  Instead the transformer must look for an identifier that ``means the same thing'' in the usage environment as the symbol else means in the transformer environment.

 -- Function: identifier=? environment1 identifier1 environment2 identifier2
     ENVIRONMENT1 and ENVIRONMENT2 must be syntactic environments, and IDENTIFIER1 and IDENTIFIER2 must be identifiers.  identifier=? returns #t if the meaning of IDENTIFIER1 in ENVIRONMENT1 is the same as that of IDENTIFIER2 in ENVIRONMENT2, otherwise it returns #f. Examples:

          (let-syntax
              ((foo
                (transformer
                 (lambda (form env)
                   (capture-syntactic-environment
                    (lambda (transformer-env)
                      (identifier=? transformer-env 'x env 'x)))))))
            (list (foo)
                  (let ((x 3))
                    (foo))))
             => (#t #f)

          (let-syntax ((bar foo))
            (let-syntax
                ((foo
                  (transformer
                   (lambda (form env)
                     (capture-syntactic-environment
                      (lambda (transformer-env)
                        (identifier=? transformer-env 'foo
                                      env (cadr form))))))))
              (list (foo foo)
                    (foobar))))
             => (#f #t)

Acknowledgements
................

The syntactic closures facility was invented by Alan Bawden and Jonathan Rees.  The use of aliases to implement syntax-rules was invented by Alan Bawden (who prefers to call them synthetic names).  Much of this proposal is derived from an earlier proposal by Alan Bawden.

Syntax-Case Macros
==================

(require 'syntax-case)

 -- Function: macro:expand expression
 -- Function: syncase:expand expression
     Returns scheme code with the macros and derived expression types of EXPRESSION expanded to primitive expression types.

 -- Function: macro:eval expression
 -- Function: syncase:eval expression
     macro:eval returns the value of EXPRESSION in the current top level environment.  EXPRESSION can contain macro definitions. Side effects of EXPRESSION will affect the top level environment.

 -- Procedure: macro:load filename
 -- Procedure: syncase:load filename
     FILENAME should be a string.  If filename names an existing file, the macro:load procedure reads Scheme source code expressions and definitions from the file and evaluates them sequentially.  These source code expressions and definitions may contain macro definitions. The macro:load procedure does not affect the values returned by current-input-port and current-output-port.

This is version 2.1 of syntax-case, the low-level macro facility proposed and implemented by Robert Hieb and R. Kent Dybvig.

This version is further adapted by Harald Hanche-Olsen <hanche@imf.unit.no> to make it compatible with, and easily usable with, SLIB.  Mainly, these adaptations consisted of:

  * Removing white space from expand.pp to save space in the distribution.  This file is not meant for human readers anyway...

  * Removed a couple of Chez scheme dependencies.

  * Renamed global variables used to minimize the possibility of name conflicts.

  * Adding an SLIB-specific initialization file.

  * Removing a couple extra files, most notably the documentation (but see below).

If you wish, you can see exactly what changes were done by reading the shell script in the file syncase.sh.

The two PostScript files were omitted in order to not burden the SLIB distribution with them.  If you do intend to use syntax-case, however, you should get these files and print them out on a PostScript printer.  They are available with the original syntax-case distribution by anonymous FTP in cs.indiana.edu:/pub/scheme/syntax-case.

In order to use syntax-case from an interactive top level, execute:

     (require 'syntax-case)
     (require 'repl)
     (repl:top-level macro:eval)

See the section Repl (see Repl) for more information.

To check operation of syntax-case get cs.indiana.edu:/pub/scheme/syntax-case, and type

     (require 'syntax-case)
     (syncase:sanity-check)

Beware that syntax-case takes a long time to load -- about 20s on a SPARCstation SLC (with SCM) and about 90s on a Macintosh SE/30 (with Gambit).

Notes
-----

All R4RS syntactic forms are defined, including delay.  Along with delay are simple definitions for make-promise (into which delay expressions expand) and force.

syntax-rules and with-syntax (described in TR356) are defined.

syntax-case is actually defined as a macro that expands into calls to the procedure syntax-dispatch and the core form syntax-lambda; do not redefine these names.

Several other top-level bindings not documented in TR356 are created:

  * the ``hooks'' in hooks.ss

  * the build- procedures in output.ss

  * expand-syntax (the expander)

The syntax of define has been extended to allow (define ID), which assigns ID to some unspecified value.

We have attempted to maintain R4RS compatibility where possible.  The incompatibilities should be confined to hooks.ss.  Please let us know if there is some incompatibility that is not flagged as such.

Send bug reports, comments, suggestions, and questions to Kent Dybvig (dyb@iuvax.cs.indiana.edu).

Note from maintainer
--------------------

Included with the syntax-case files was structure.scm which defines a macro define-structure.  There is no documentation for this macro and it is not used by any code in SLIB.

Fluid-Let
=========

(require 'fluid-let)

 -- Syntax: fluit-let (BINDINGS ...) FORMS...

     (fluid-let ((VARIABLE INIT) ...)
        EXPRESSION EXPRESSION ...)

The INITs are evaluated in the current environment (in some unspecified order), the current values of the VARIABLEs are saved, the results are assigned to the VARIABLEs, the EXPRESSIONs are evaluated sequentially in the current environment, the VARIABLEs are restored to their original values, and the value of the last EXPRESSION is returned.

The syntax of this special form is similar to that of let, but fluid-let temporarily rebinds existing VARIABLEs.  Unlike let, fluid-let creates no new bindings; instead it assigns the values of each INIT to the binding (determined by the rules of lexical scoping) of its corresponding VARIABLE.

Yasos
=====

(require 'oop) or (require 'yasos)

`Yet Another Scheme Object System'.  A simple object system for Scheme based on the paper by Norman Adams and Jonathan Rees: Object Oriented Programming in Scheme, Proceedings of the 1988 ACM Conference on LISP and Functional Programming, July 1988 [ACM #552880].

Terms
-----

Object
     Any Scheme data object.

Instance
     An instance of the OO system; an object.

Operation
     A METHOD.

Notes:
     The object system supports multiple inheritance.  An instance can inherit from 0 or more ancestors.  In the case of multiple inherited operations with the same identity, the operation used is that from the first ancestor which contains it (in the ancestor let).  An operation may be applied to any Scheme data object---not just instances. As code which creates instances is just code, there are no classes and no meta-ANYTHING.  Method dispatch is by a procedure call a la CLOS rather than by `send' syntax a la Smalltalk.

Disclaimer:
     There are a number of optimizations which can be made.  This implementation is expository (although performance should be quite reasonable).  See the L&FP paper for some suggestions.

Interface
---------

 -- Syntax: define-operation (opname self arg ...) DEFAULT-BODY
     Defines a default behavior for data objects which don't handle the operation OPNAME.  The default default behavior (for an empty DEFAULT-BODY) is to generate an error.

 -- Syntax: define-predicate opname?
     Defines a predicate OPNAME?, usually used for determining the type of an object, such that (OPNAME? OBJECT) returns #t if OBJECT has an operation OPNAME? and #f otherwise.

 -- Syntax: object ((NAME SELF ARG ...) BODY) ...
     Returns an object (an instance of the object system) with operations. Invoking (NAME OBJECT ARG ... executes the BODY of the OBJECT with SELF bound to OBJECT and with argument(s) ARG....

 -- Syntax: object-with-ancestors ((ancestor1 init1) ...) operation ...
     A let-like form of object for multiple inheritance.  It returns an object inheriting the behaviour of ANCESTOR1 etc.  An operation will be invoked in an ancestor if the object itself does not provide such a method.  In the case of multiple inherited operations with the same identity, the operation used is the one found in the first ancestor in the ancestor list.

 -- Syntax: operate-as component operation self arg ...
     Used in an operation definition (of SELF) to invoke the OPERATION in an ancestor COMPONENT but maintain the object's identity.  Also known as ``send-to-super''.

 -- Procedure: print obj port
     A default print operation is provided which is just (format PORT OBJ) (see Format) for non-instances and prints OBJ preceded by #<INSTANCE> for instances.  Note that print is also defined in the debug module (see Debug) and these will conflict.

 -- Function: size obj
     The default method returns the number of elements in OBJ if it is a vector, string or list, 2 for a pair, 1 for a character and by default id an error otherwise.  Objects such as collections (see Collections) may override the default in an obvious way.

Setters
-------

Setters implement `generalized locations' for objects associated with some sort of mutable state.  A getter operation retrieves a value from a generalized location and the corresponding setter operation stores a value into the location.  Only the getter is named -- the setter is specified by a procedure call as below.  (Dylan uses special syntax.)  Typically, but not necessarily, getters are access operations to extract values from Yasos objects (see Yasos).  Several setters are predefined, corresponding to getters car, cdr, string-ref and vector-ref e.g., (setter car) is equivalent to set-car!.

This implementation of setters is similar to that in Dylan(TM) (Dylan: An object-oriented dynamic language, Apple Computer Eastern Research and Technology).  Common LISP provides similar facilities through setf.

 -- Function: setter getter
     Returns the setter for the procedure GETTER.  E.g., since string-ref is the getter corresponding to a setter which is actually string-set!:

          (define foo "foo")
          ((setter string-ref) foo 0 #\F) ; set element 0 of foo
          foo => "Foo"

 -- Syntax: set place new-value
     If PLACE is a variable name, set is equivalent to set!.  Otherwise, PLACE must have the form of a procedure call, where the procedure name refers to a getter and the call indicates an accessible generalized location, i.e., the call would return a value. The return value of set is usually unspecified unless used with a setter whose definition guarantees to return a useful value.

          (set (string-ref foo 2) #\O)  ; generalized location with getter
          foo => "FoO"
          (set foo "foo")               ; like set!
          foo => "foo"

 -- Procedure: add-setter getter setter
     Add procedures GETTER and SETTER to the (inaccessible) list of valid setter/getter pairs.  SETTER implements the store operation corresponding to the GETTER access operation for the relevant state.  The return value is unspecified.

 -- Procedure: remove-setter-for getter
     Removes the setter corresponding to the specified GETTER from the list of valid setters.  The return value is unspecified.

 -- Syntax: define-access-operation getter-name
     Shorthand for a Yasos define-operation defining an operation GETTER-NAME that objects may support to return the value of some mutable state.  The default operation is to signal an error.  The return value is unspecified.

Examples
--------

     (define-operation (print obj port)
       (format port
               (if (instance? obj) "#<instance>" "~s")
               obj))

     (define-operation (SIZE obj)
       (cond
        ((vector? obj) (vector-length obj))
        ((list?   obj) (length obj))
        ((pair?   obj) 2)
        ((string? obj) (string-length obj))
        ((char?   obj) 1)
        (else
         (error "Operation not supported: size" obj))))

     (define-predicate cell?)
     (define-operation (fetch obj))
     (define-operation (store! obj newValue))

     (define (make-cell value)
       (object
        ((cell? self) #t)
        ((fetch self) value)
        ((store! self newValue)
         (set! value newValue)
         newValue)
        ((size self) 1)
        ((print self port)
         (format port "#<Cell: ~s>" (fetch self)))))

     (define-operation (discard obj value)
       (format #t "Discarding ~s~%" value))

     (define (make-filtered-cell value filter)
       (object-with-ancestors ((cell (make-cell value)))
                              ((store! self newValue)
                               (if (filter newValue)
                                   (store! cell newValue)
                                   (discard self newValue)))))

     (define-predicate array?)
     (define-operation (array-ref array index))
     (define-operation (array-set! array index value))

     (define (make-array num-slots)
       (let ((anArray (make-vector num-slots)))
         (object
          ((array? self) #t)
          ((size self) num-slots)
          ((array-ref self index)           (vector-ref  anArray index))
          ((array-set! self index newValue) (vector-set! anArray index newValue))
          ((print self port) (format port "#<Array ~s>" (size self))))))

     (define-operation (position obj))
     (define-operation (discarded-value obj))

     (define (make-cell-with-history value filter size)
       (let ((pos 0) (most-recent-discard #f))
         (object-with-ancestors
          ((cell (make-filtered-call value filter))
           (sequence (make-array size)))
          ((array? self) #f)
          ((position self) pos)
          ((store! self newValue)
           (operate-as cell store! self newValue)
           (array-set! self pos newValue)
           (set! pos (+ pos 1)))
          ((discard self value)
           (set! most-recent-discard value))
          ((discarded-value self) most-recent-discard)
          ((print self port)
           (format port "#<Cell-with-history ~s>" (fetch self))))))

     (define-access-operation fetch)
     (add-setter fetch store!)
     (define foo (make-cell 1))
     (print foo #f)
     => "#<Cell: 1>"
     (set (fetch foo) 2)
     =>
     (print foo #f)
     => "#<Cell: 2>"
     (fetch foo)
     => 2

Numerics
********

Bit-Twiddling
=============

(require 'logical)

The bit-twiddling functions are made available through the use of the logical package.  logical is loaded by inserting (require 'logical) before the code that uses these functions.

 -- Function: logand n1 n1
     Returns the integer which is the bit-wise AND of the two integer arguments.

     Example:

          (number->string (logand #b1100 #b1010) 2)
             => "1000"

 -- Function: logior n1 n2
     Returns the integer which is the bit-wise OR of the two integer arguments.

     Example:

          (number->string (logior #b1100 #b1010) 2)
             => "1110"

 -- Function: logxor n1 n2
     Returns the integer which is the bit-wise XOR of the two integer arguments.

     Example:

          (number->string (logxor #b1100 #b1010) 2)
             => "110"

 -- Function: lognot n
     Returns the integer which is the 2s-complement of the integer argument.

     Example:

          (number->string (lognot #b10000000) 2)
             => "-10000001"
          (number->string (lognot #b0) 2)
             => "-1"

 -- Function: logtest j k

          (logtest j k) == (not (zero? (logand j k)))

          (logtest #b0100 #b1011) => #f
          (logtest #b0100 #b0111) => #t

 -- Function: logbit? index j

          (logbit? index j) == (logtest (integer-expt 2 index) j)

          (logbit? 0 #b1101) => #t
          (logbit? 1 #b1101) => #f
          (logbit? 2 #b1101) => #t
          (logbit? 3 #b1101) => #t
          (logbit? 4 #b1101) => #f

 -- Function: ash int count
     Returns an integer equivalent to (inexact->exact (floor (* INT (expt 2 COUNT)))).

     Example:

          (number->string (ash #b1 3) 2)
             => "1000"
          (number->string (ash #b1010 -1) 2)
             => "101"

 -- Function: logcount n
     Returns the number of bits in integer N.  If integer is positive, the 1-bits in its binary representation are counted.  If negative, the 0-bits in its two's-complement binary representation are counted.  If 0, 0 is returned.

     Example:

          (logcount #b10101010)
             => 4
          (logcount 0)
             => 0
          (logcount -2)
             => 1

 -- Function: integer-length n
     Returns the number of bits neccessary to represent N.

     Example:

          (integer-length #b10101010)
             => 8
          (integer-length 0)
             => 0
          (integer-length #b1111)
             => 4

 -- Function: integer-expt n k
     Returns N raised to the non-negative integer exponent K.

     Example:

          (integer-expt 2 5)
             => 32
          (integer-expt -3 3)
             => -27

 -- Function: bit-extract n start end
     Returns the integer composed of the START (inclusive) through END (exclusive) bits of N.  The STARTth bit becomes the 0-th bit in the result.

     Example:

          (number->string (bit-extract #b1101101010 0 4) 2)
             => "1010"
          (number->string (bit-extract #b1101101010 4 9) 2)
             => "10110"

Modular Arithmetic
==================

(require 'modular)

 -- Function: extended-euclid n1 n2
     Returns a list of 3 integers (d x y) such that d = gcd(N1, N2) = N1 * x + N2 * y.

     For all of these procedure all arguments should be exact non-negative integers such that k1 > k2 and k1 > k3.  The returned value will be an exact non-negative integer less than k1.  If all the arguments are fixnums the computation will use only fixnums.

 -- Function: modular:invert k1 k2
     Returns an integer n such that 1 = (n * k2) mod k1.  If k2 has no inverse mod k1 an error is signaled.

 -- Function: modular:negate k1 k2
     Returns (-k2) mod k1.

 -- Function: modular:+ k1 k2 k3
     Returns (k2 + k3) mod k1.

 -- Function: modular:- k1 k2 k3
     Returns (k2 - k3) mod k1.

 -- Function: modular:* k1 k2 k3
     Returns (k2 * k3) mod k1.

 -- Function: modular:expt k1 k2 k3
     Returns (k2 ^ k3) mod k1.

Prime Testing and Generation
============================

(require 'primes)

This package tests and generates prime numbers.  The strategy used is as follows:

  * First, use trial division by small primes (primes less than 1000) to quickly weed out composites with small factors.  As a side benefit, this makes the test precise for numbers up to one million.

  * Second, apply the Miller-Rabin primality test to detect (with high probability) any remaining composites.

The Miller-Rabin test is a Monte-Carlo test---in other words, it's fast and it gets the right answer with high probability.  For a candidate that is prime, the Miller-Rabin test is certain to report "prime"; it will never report "composite".  However, for a candidate that is composite, there is a (small) probability that the Miller-Rabin test will erroneously report "prime".  This probability can be made arbitarily small by adjusting the number of iterations of the Miller-Rabin test.

 -- Function: probably-prime? candidate . iter
     Returns #t if candidate is probably prime.  The optional parameter iter controls the number of iterations of the Miller-Rabin test.  The probability of a composite candidate being mistaken for a prime is at most (1/4)^iter.  The default value of iter is 15, which makes the probability less than 1 in 10^9.

 -- Function: primes start count . iter
     Returns a list of the first count odd probable primes less than or equal to start.  The optional parameter iter controls the number of iterations of the Miller-Rabin test for each candidate. The probability of a composite candidate being mistaken for a prime is at most (1/4)^iter.  The default value of iter is 15, which makes the probability less than 1 in 10^9.

Theory
------

Rabin and Miller's result can be summarized as follows.  Let p (the candidate prime) be any odd integer greater than 2.  Let b (the "base") be an integer in the range 2 ... p-1.  There is a fairly simple Boolean function---call it C, for "Composite"---with the following properties:

  * If p is prime, C(p, b) is false for all b in the range 2 ... p-1.

  * If p is composite, C(p, b) is false for at most 1/4 of all b in the range  2 ... p-1.  (If the test fails for base b, p is called a strong pseudo-prime to base b.)

For details of C, and why it fails for at most 1/4 of the potential bases, please consult a book on number theory or cryptography such as "A Course in Number Theory and Cryptography" by Neal Koblitz, published by Springer-Verlag 1994.

There is nothing probablistic about this result.  It's true for all p.  If we had time to test (1/4)p + 1 different bases, we could definitively determine the primality of p.  For large candidates, that would take much too long---much longer than the simple approach of dividing by all numbers up to sqrt(p).  This is where probability enters the picture.

Suppose we have some candidate prime p.  Pick a random integer b in the range 2 ... p-1.  Compute C(p,b).  If p is prime, the result will certainly be false.  If p is composite, the probability is at most 1/4 that the result will be false (demonstrating that p is a strong pseudoprime to base b). The test can be repeated with other random bases.  If p is prime, each test is certain to return false.  If p is composite, the probability of C(p,b) returning false is at most 1/4 for each test.  Since the b are chosen at random, the tests outcomes are independent. So if p is composite and the test is repeated, say, 15 times, the probability of it returning false all fifteen times is at most (1/4)^15, or about 10^-9.  If the test is repeated 30 times, the probability of failure drops to at most 8.3e-25.

Rabin and Miller's result holds for all candidates p. However, if the candidate p is picked at random, the probability of the Miller-Rabin test failing is much less than the computed bound. This is because, for most composite numbers, the fraction of bases that cause the test to fail is much less than 1/4.  For example, if you pick a random odd number less than 1000 and apply the Miller-Rabin test with only 3 random bases, the computed failure bound is (1/4)^3, or about 1.6e-2.  However, the actual probability of failure is much less---about 7.2e-5.  If you accidentally pick 703 to test for primality, the probability of failure is (161/703)^3, or about 1.2e-2, which is almost as high as the computed bound.  This is because 703 is a strong pseudoprime to 161 bases.  But if you pick at random there is only a small chance of picking 703, and no other number less than 1000 has that high a percentage of pseudoprime bases.

The Miller-Rabin test is sometimes used in a slightly different fashion, where it can, at least in principle, cause problems.  The weaker version uses small prime bases instead of random bases.  If you are picking candidates at random and testing for primality, this works well since very few composites are strong pseudo-primes to small prime bases.  (For example, there is only one composite less than 2.5e10 that is a strong pseudo-prime to the bases 2, 3, 5, and 7.)  The problem with this approach is that once a candidate has been picked, the test is deterministic.  This distinction is subtle, but real.  With the randomized test, for any candidate you pick---even if your candidate-picking procedure is strongly biased towards troublesome numbers, the test will work with high probability.  With the deterministic version, for any particular candidate, the test will either work (with probability 1), or fail (with probability 1).  It won't fail for very many candidates, but that won't be much consolation if your candidate-picking procedure is somehow biased toward troublesome numbers.

Prime Factorization
===================

(require 'factor)

 -- Function: factor k
     Returns a list of the prime factors of K.  The order of the factors is unspecified.  In order to obtain a sorted list do (sort! (factor k) <).

Note: The rest of these procedures implement the Solovay-Strassen primality test.  This test has been superseeded by the faster see probably-prime?.  However these are left here as they take up little space and may be of use to an implementation without bignums.

See Robert Solovay and Volker Strassen, A Fast Monte-Carlo Test for Primality, SIAM Journal on Computing, 1977, pp 84-85.

 -- Function: jacobi-symbol p q
     Returns the value (+1, -1, or 0) of the Jacobi-Symbol of exact non-negative integer P and exact positive odd integer Q.

 -- Function: prime? p
     Returns #f if P is composite; #t if P is prime.  There is a slight chance (expt 2 (- prime:trials)) that a composite will return #t.

 -- Function: prime:trials
     Is the maxinum number of iterations of Solovay-Strassen that will be done to test a number for primality.

Random Numbers
==============

(require 'random)

 -- Procedure: random n
 -- Procedure: random n state
     Accepts a positive integer or real N and returns a number of the same type between zero (inclusive) and N (exclusive).  The values returned have a uniform distribution.

     The optional argument STATE must be of the type produced by (make-random-state).  It defaults to the value of the variable *random-state*.  This object is used to maintain the state of the pseudo-random-number generator and is altered as a side effect of the random operation.

 -- Variable: *random-state*
     Holds a data structure that encodes the internal state of the random-number generator that random uses by default.  The nature of this data structure is implementation-dependent.  It may be printed out and successfully read back in, but may or may not function correctly as a random-number state object in another implementation.

 -- Procedure: make-random-state
 -- Procedure: make-random-state state
     Returns a new object of type suitable for use as the value of the variable *random-state* and as a second argument to random.  If argument STATE is given, a copy of it is returned.  Otherwise a copy of *random-state* is returned.

If inexact numbers are support by the Scheme implementation, randinex.scm will be loaded as well.  randinex.scm contains procedures for generating inexact distributions.

 -- Procedure: random:uniform state
     Returns an uniformly distributed inexact real random number in the range between 0 and 1.

 -- Procedure: random:solid-sphere! vect
 -- Procedure: random:solid-sphere! vect state
     Fills VECT with inexact real random numbers the sum of whose squares is less than 1.0.  Thinking of VECT as coordinates in space of dimension N = (vector-length VECT), the coordinates are uniformly distributed within the unit N-shere. The sum of the squares of the numbers is returned.

 -- Procedure: random:hollow-sphere! vect
 -- Procedure: random:hollow-sphere! vect state
     Fills VECT with inexact real random numbers the sum of whose squares is equal to 1.0.  Thinking of VECT as coordinates in space of dimension n = (vector-length VECT), the coordinates are uniformly distributed over the surface of the unit n-shere.

 -- Procedure: random:normal
 -- Procedure: random:normal state
     Returns an inexact real in a normal distribution with mean 0 and standard deviation 1.  For a normal distribution with mean M and standard deviation D use (+ M (* D (random:normal))).

 -- Procedure: random:normal-vector! vect
 -- Procedure: random:normal-vector! vect state
     Fills VECT with inexact real random numbers which are independent and standard normally distributed (i.e., with mean 0 and variance 1).

 -- Procedure: random:exp
 -- Procedure: random:exp state
     Returns an inexact real in an exponential distribution with mean 1.  For an exponential distribution with mean U use (* U (random:exp)).

Plotting on Character Devices
=============================

(require 'charplot)

The plotting procedure is made available through the use of the charplot package.  charplot is loaded by inserting (require 'charplot) before the code that uses this procedure.

 -- Variable: charplot:height
     The number of rows to make the plot vertically.

 -- Variable: charplot:width
     The number of columns to make the plot horizontally.

 -- Procedure: plot! coords x-label y-label
     COORDS is a list of pairs of x and y coordinates.  X-LABEL and Y-LABEL are strings with which to label the x and y axes.

     Example:

          (require 'charplot)
          (set! charplot:height 19)
          (set! charplot:width 45)

          (define (make-points n)
            (if (zero? n)
                '()
                (cons (cons (/ n 6) (sin (/ n 6))) (make-points (1- n)))))

          (plot! (make-points 37) "x" "Sin(x)")
          -|

            Sin(x)   ______________________________________________
                1.25|-                                             |
                    |                                              |
                   1|-       ****                                  |
                    |      **    **                                |
            750.0e-3|-    *        *                               |
                    |    *          *                              |
            500.0e-3|-  *            *                             |
                    |  *                                           |
            250.0e-3|-                *                            |
                    | *                *                           |
                   0|-------------------*--------------------------|
                    |                                     *        |
           -250.0e-3|-                   *               *         |
                    |                     *             *          |
           -500.0e-3|-                     *                       |
                    |                       *          *           |
           -750.0e-3|-                       *        *            |
                    |                         **    **             |
                  -1|-                          ****               |
                    |____________:_____._____:_____._____:_________|
                  x              2           4

Procedures
**********

Anything that doesn't fall neatly into any of the other categories winds up here.

Batch
=====

(require 'batch)

The batch procedures provide a way to write and execute portable scripts for a variety of operating systems.  Each batch: procedure takes as its first argument a parameter-list (see Parameter lists).  This parameter-list argument PARMS contains named associations.  Batch currently uses 2 of these:

batch-port
     The port on which to write lines of the batch file.

batch-dialect
     The syntax of batch file to generate.  Currently supported are:

       * unix

       * dos

       * vms

       * system

       * *unknown*

batch.scm uses 2 enhanced relational tables (see Database Utilities) to store information linking the names of operating-systems to batch-dialectes.

 -- Function: batch:initialize! database
     Defines operating-system and batch-dialect tables and adds the domain operating-system to the enhanced relational database DATABASE.

 -- Variable: batch:platform
     Is batch's best guess as to which operating-system it is running under. batch:platform is set to (software-type) (see Configuration) unless (software-type) is unix, in which case finer distinctions are made.

 -- Function: batch:call-with-output-script parms file proc
     PROC should be a procedure of one argument.  If FILE is an output-port, batch:call-with-output-script writes an appropriate header to FILE and then calls PROC with FILE as the only argument.  If FILE is a string, batch:call-with-output-script opens a output-file of name FILE, writes an appropriate header to FILE, and then calls PROC with the newly opened port as the only argument.  Otherwise, batch:call-with-output-script acts as if it was called with the result of (current-output-port) as its third argument.

The rest of the batch: procedures write (or execute if batch-dialect is system) commands to the batch port which has been added to PARMS or (copy-tree PARMS) by the code:

     (adjoin-parameters! PARMS (list 'batch-port PORT))

These functions return a non-false value if the command was successfully translated into the batch dialect and #f if not.  In the case of the system dialect, the value returned by the operation is returned.

 -- Function: batch:system parms string1 string2 ...
     Writes a command to the batch-port in PARMS which executes the program named STRING1 with arguments STRING2 ....

 -- Function: batch:run-script parms string1 string2 ...
     Writes a command to the batch-port in PARMS which executes the batch script named STRING1 with arguments STRING2 ....

     Note: batch:run-script and batch:system are not the same for some operating systems (VMS).

 -- Function: batch:comment parms line1 ...
     Writes comment lines LINE1 ... to the batch-port in PARMS.

 -- Function: batch:lines->file parms file line1 ...
     Writes commands to the batch-port in PARMS which create a file named FILE with contents LINE1 ....

 -- Function: batch:delete-file parms file
     Writes a command to the batch-port in PARMS which deletes the file named FILE.

 -- Function: batch:rename-file parms old-name new-name
     Writes a command to the batch-port in PARMS which renames the file OLD-NAME to NEW-NAME.

In addition, batch provides some small utilities very useful for writing scripts:

 -- Function: replace-suffix str old new
     Returns a new string similar to str but with the suffix string OLD removed and the suffix string NEW appended.  If the end of STR does not match OLD, an error is signaled.

 -- Function: string-join joiner string1 ...
     Returns a new string consisting of all the strings STRING1 ... in order appended together with the string JOINER between each adjacent pair.

 -- Function: os->batch-dialect osname
     Returns its best guess for the batch-dialect to be used for the operating-system named OSNAME.  os->batch-dialect uses the tables added to DATABASE by batch:initialize!.

Here is an example of the use of most of batch's procedures:

     (require 'database-utilities)
     (require 'parameters)
     (require 'batch)

     (define batch (create-database #f 'alist-table))
     (batch:initialize! batch)

     (define my-parameters
       (list (list 'batch-dialect (os->batch-dialect batch:platform))
             (list 'platform batch:platform)
             (list 'batch-port (current-output-port)))) ;gets filled in later

     (batch:call-with-output-script
      my-parameters
      "my-batch"
      (lambda (batch-port)
        (adjoin-parameters! my-parameters (list 'batch-port batch-port))
        (and
         (batch:comment my-parameters
                        "================ Write file with C program.")
         (batch:rename-file my-parameters "hello.c" "hello.c~")
         (batch:lines->file my-parameters "hello.c"
                            "#include <stdio.h>"
                            "int main(int argc, char **argv)"
                            "{"
                            "  printf(\"hello world\\n\");"
                            "  return 0;"
                            "}" )
         (batch:system my-parameters "cc" "-c" "hello.c")
         (batch:system my-parameters "cc" "-o" "hello"
                       (replace-suffix "hello.c" ".c" ".o"))
         (batch:system my-parameters "hello")
         (batch:delete-file my-parameters "hello")
         (batch:delete-file my-parameters "hello.c")
         (batch:delete-file my-parameters "hello.o")
         (batch:delete-file my-parameters "my-batch")
         )))

Produces the file my-batch:

     #!/bin/sh
     # "my-batch" build script created Sat Jun 10 21:20:37 1995
     # ================ Write file with C program.
     mv -f hello.c hello.c~
     rm -f hello.c
     echo '#include <stdio.h>'>>hello.c
     echo 'int main(int argc, char **argv)'>>hello.c
     echo '{'>>hello.c
     echo '  printf("hello world\n");'>>hello.c
     echo '  return 0;'>>hello.c
     echo '}'>>hello.c
     cc -c hello.c
     cc -o hello hello.o
     hello
     rm -f hello
     rm -f hello.c
     rm -f hello.o
     rm -f my-batch

When run, my-batch prints:

     bash$ my-batch
     mv: hello.c: No such file or directory
     hello world

Common List Functions
=====================

(require 'common-list-functions)

The procedures below follow the Common LISP equivalents apart from optional arguments in some cases.

List construction
-----------------

 -- Function: make-list k . init
     make-list creates and returns a list of K elements.  If INIT is included, all elements in the list are initialized to INIT.

     Example:

          (make-list 3)
             => (#<unspecified> #<unspecified> #<unspecified>)
          (make-list 5 'foo)
             => (foo foo foo foo foo)

 -- Function: list* x . y
     Works like list except that the cdr of the last pair is the last argument unless there is only one argument, when the result is just that argument.  Sometimes called cons*.  E.g.:

          (list* 1)
             => 1
          (list* 1 2 3)
             => (1 2 . 3)
          (list* 1 2 '(3 4))
             => (1 2 3 4)
          (list* ARGS '())
             == (list ARGS)

 -- Function: copy-list lst
     copy-list makes a copy of LST using new pairs and returns it. Only the top level of the list is copied, i.e., pairs forming elements of the copied list remain eq? to the corresponding elements of the original; the copy is, however, not eq? to the original, but is equal? to it.

     Example:

          (copy-list '(foo foo foo))
             => (foo foo foo)
          (define q '(foo bar baz bang))
          (define p q)
          (eq? p q)
             => #t
          (define r (copy-list q))
          (eq? q r)
             => #f
          (equal? q r)
             => #t
          (define bar '(bar))
          (eq? bar (car (copy-list (list bar 'foo))))
          => #t

Lists as sets
-------------

eq? is used to test for membership by all the procedures below which treat lists as sets.

 -- Function: adjoin e l
     adjoin returns the adjoint of the element E and the list L.  That is, if E is in L, adjoin returns L, otherwise, it returns (cons E L).

     Example:

          (adjoin 'baz '(bar baz bang))
             => (bar baz bang)
          (adjoin 'foo '(bar baz bang))
             => (foo bar baz bang)

 -- Function: union l1 l2
     union returns the combination of L1 and L2 with duplicates removed.

     Example:

          (union '(1 2 3 4) '(5 6 7 8))
             => (4 3 2 1 5 6 7 8)
          (union '(1 2 2 1) '(3 4 1 8))
             => (2 3 4 1 8)

 -- Function: intersection l1 l2
     intersection returns all elements that are in both L1 and L2.

     Example:

          (intersection '(1 2 3 4) '(3 4 5 6))
             => (3 4)
          (intersection '(1 2 3 4) '(5 6 7 8))
             => ()

 -- Function: set-difference l1 l2
     set-difference returns the union of all elements that are in L1 but not in L2.

     Example:

          (set-difference '(1 2 3 4) '(3 4 5 6))
             => (1 2)
          (set-difference '(1 2 3 4) '(1 2 3 4 5 6))
             => ()

 -- Function: member-if pred lst
     member-if returns LST if (PRED ELEMENT) is #t for any ELEMENT in LST.  Returns #f if PRED does not apply to any ELEMENT in LST.

     Example:

          (member-if vector? '(1 2 3 4))
             => #f
          (member-if number? '(1 2 3 4))
             => (1 2 3 4)

 -- Function: some pred lst . more-lsts
     PRED is a boolean function of as many arguments as there are list arguments to some i.e., LST plus any optional arguments. PRED is applied to successive elements of the list arguments in order.  some returns #t as soon as one of these applications returns #t, and is #f if none returns #t.  All the lists should have the same length.

     Example:

          (some odd? '(1 2 3 4))
             => #t

          (some odd? '(2 4 6 8))
             => #f

          (some > '(2 3) '(1 4))
             => #f

 -- Function: every pred lst . more-lsts
     every is analogous to some except it returns #t if every application of PRED is #t and #f otherwise.

     Example:

          (every even? '(1 2 3 4))
             => #f

          (every even? '(2 4 6 8))
             => #t

          (every > '(2 3) '(1 4))
             => #f

 -- Function: notany pred . lst
     notany is analogous to some but returns #t if no application of PRED returns #t or #f as soon as any one does.

 -- Function: notevery pred . lst
     notevery is analogous to some but returns #t as soon as an application of PRED returns #f, and #f otherwise.

     Example:

          (notevery even? '(1 2 3 4))
             => #t

          (notevery even? '(2 4 6 8))
             => #f

 -- Function: find-if pred lst
     find-if searches for the first ELEMENT in LST such that (PRED ELEMENT) returns #t.  If it finds any such ELEMENT in LST, ELEMENT is returned. Otherwise, #f is returned.

     Example:

          (find-if number? '(foo 1 bar 2))
             => 1

          (find-if number? '(foo bar baz bang))
             => #f

          (find-if symbol? '(1 2 foo bar))
             => foo

 -- Function: remove elt lst
     remove removes all occurrences of ELT from LST using eqv? to test for equality and returns everything that's left. N.B.: other implementations (Chez, Scheme->C and T, at least) use equal? as the equality test.

     Example:

          (remove 1 '(1 2 1 3 1 4 1 5))
             => (2 3 4 5)

          (remove 'foo '(bar baz bang))
             => (bar baz bang)

 -- Function: remove-if pred lst
     remove-if removes all ELEMENTs from LST where (PRED ELEMENT) is #t and returns everything that's left.

     Example:

          (remove-if number? '(1 2 3 4))
             => ()

          (remove-if even? '(1 2 3 4 5 6 7 8))
             => (1 3 5 7)

 -- Function: remove-if-not pred lst
     remove-if-not removes all ELEMENTs from LST for which (PRED ELEMENT) is #f and returns everything that's left.

     Example:

          (remove-if-not number? '(foo bar baz))
             => ()
          (remove-if-not odd? '(1 2 3 4 5 6 7 8))
             => (1 3 5 7)

 -- Function: has-duplicates? lst
     returns #t if 2 members of LST are equal?, #f otherwise. Example:

          (has-duplicates? '(1 2 3 4))
             => #f

          (has-duplicates? '(2 4 3 4))
             => #t

Lists as sequences
------------------

 -- Function: position obj lst
     position returns the 0-based position of OBJ in LST, or #f if OBJ does not occur in LST.

     Example:

          (position 'foo '(foo bar baz bang))
             => 0
          (position 'baz '(foo bar baz bang))
             => 2
          (position 'oops '(foo bar baz bang))
             => #f

 -- Function: reduce p lst
     reduce combines all the elements of a sequence using a binary operation (the combination is left-associative).  For example, using +, one can add up all the elements.  reduce allows you to apply a function which accepts only two arguments to more than 2 objects.  Functional programmers usually refer to this as foldl. collect:reduce (see Collections) provides a version of collect generalized to collections.

     Example:

          (reduce + '(1 2 3 4))
             => 10
          (define (bad-sum . l) (reduce + l))
          (bad-sum 1 2 3 4)
             == (reduce + (1 2 3 4))
             == (+ (+ (+ 1 2) 3) 4)
          => 10
          (bad-sum)
             == (reduce + ())
             => ()
          (reduce string-append '("hello" "cruel" "world"))
             == (string-append (string-append "hello" "cruel") "world")
             => "hellocruelworld"
          (reduce anything '())
             => ()
          (reduce anything '(x))
             => x

     What follows is a rather non-standard implementation of reverse in terms of reduce and a combinator elsewhere called C.

          ;;; Contributed by Jussi Piitulainen (jpiitula@ling.helsinki.fi)

          (define commute
            (lambda (f)
              (lambda (x y)
                (f y x))))

          (define reverse
            (lambda (args)
              (reduce-init (commute cons) args)))

 -- Function: reduce-init p init lst
     reduce-init is the same as reduce, except that it implicitly inserts INIT at the start of the list.  reduce-init is preferred if you want to handle the null list, the one-element, and lists with two or more elements consistently.  It is common to use the operator's idempotent as the initializer.  Functional programmers usually call this foldl.

     Example:

          (define (sum . l) (reduce-init + 0 l))
          (sum 1 2 3 4)
             == (reduce-init + 0 (1 2 3 4))
             == (+ (+ (+ (+ 0 1) 2) 3) 4)
             => 10
          (sum)
             == (reduce-init + 0 '())
             => 0

          (reduce-init string-append "@" '("hello" "cruel" "world"))
          ==
          (string-append (string-append (string-append "@" "hello")
                                         "cruel")
                         "world")
          => "@hellocruelworld"

     Given a differentiation of 2 arguments, diff, the following will differentiate by any number of variables.

          (define (diff* exp . vars)
            (reduce-init diff exp vars))

     Example:

          ;;; Real-world example:  Insertion sort using reduce-init.

          (define (insert l item)
            (if (null? l)
                (list item)
                (if (< (car l) item)
                    (cons (car l) (insert (cdr l) item))
                    (cons item l))))
          (define (insertion-sort l) (reduce-init insert '() l))

          (insertion-sort '(3 1 4 1 5)
             == (reduce-init insert () (3 1 4 1 5))
             == (insert (insert (insert (insert (insert () 3) 1) 4) 1) 5)
             == (insert (insert (insert (insert (3)) 1) 4) 1) 5)
             == (insert (insert (insert (1 3) 4) 1) 5)
             == (insert (insert (1 3 4) 1) 5)
             == (insert (1 1 3 4) 5)
             => (1 1 3 4 5)

 -- Function: butlast lst n
     butlast returns all but the last N elements of LST.

     Example:

          (butlast '(1 2 3 4) 3)
             => (1)
          (butlast '(1 2 3 4) 4)
             => ()

 -- Function: nthcdr n lst
     nthcdr takes N cdrs of LST and returns the result.  Thus (nthcdr 3 LST) == (cdddr LST)

     Example:

          (nthcdr 2 '(1 2 3 4))
             => (3 4)
          (nthcdr 0 '(1 2 3 4))
             => (1 2 3 4)

 -- Function: last lst n
     last returns the last N elements of LST.  N must be a non-negative integer.

     Example:

          (last '(foo bar baz bang) 2)
             => (baz bang)
          (last '(1 2 3) 0)
             => 0

Destructive list operations
---------------------------

These procedures may mutate the list they operate on, but any such mutation is undefined.

 -- Procedure: nconc args
     nconc destructively concatenates its arguments.  (Compare this with append, which copies arguments rather than destroying them.) Sometimes called append! (see Rev2 Procedures).

     Example:  You want to find the subsets of a set.  Here's the obvious way:

          (define (subsets set)
            (if (null? set)
                '(())
                (append (mapcar (lambda (sub) (cons (car set) sub))
                                (subsets (cdr set)))
                        (subsets (cdr set)))))

     But that does way more consing than you need.  Instead, you could replace the append with nconc, since you don't have any need for all the intermediate results.

     Example:

          (define x '(a b c))
          (define y '(d e f))
          (nconc x y)
             => (a b c d e f)
          x
             => (a b c d e f)

     nconc is the same as append! in sc2.scm.

 -- Procedure: nreverse lst
     nreverse reverses the order of elements in LST by mutating cdrs of the list.  Sometimes called reverse!.

     Example:

          (define foo '(a b c))
          (nreverse foo)
             => (c b a)
          foo
             => (a)

     Some people have been confused about how to use nreverse, thinking that it doesn't return a value.  It needs to be pointed out that

          (set! lst (nreverse lst))

     is the proper usage, not

          (nreverse lst)

     The example should suffice to show why this is the case.

 -- Procedure: delete elt lst
 -- Procedure: delete-if pred lst
 -- Procedure: delete-if-not pred lst
     Destructive versions of remove remove-if, and remove-if-not.

     Example:

          (define lst '(foo bar baz bang))
          (delete 'foo lst)
             => (bar baz bang)
          lst
             => (foo bar baz bang)

          (define lst '(1 2 3 4 5 6 7 8 9))
          (delete-if odd? lst)
             => (2 4 6 8)
          lst
             => (1 2 4 6 8)

     Some people have been confused about how to use delete, delete-if, and delete-if, thinking that they dont' return a value.  It needs to be pointed out that

          (set! lst (delete el lst))

     is the proper usage, not

          (delete el lst)

     The examples should suffice to show why this is the case.

Non-List functions
------------------

 -- Function: and? . args
     and? checks to see if all its arguments are true.  If they are, and? returns #t, otherwise, #f.  (In contrast to and, this is a function, so all arguments are always evaluated and in an unspecified order.)

     Example:

          (and? 1 2 3)
             => #t
          (and #f 1 2)
             => #f

 -- Function: or? . args
     or? checks to see if any of its arguments are true.  If any is true, or? returns #t, and #f otherwise.  (To or as and? is to and.)

     Example:

          (or? 1 2 #f)
             => #t
          (or? #f #f #f)
             => #f

 -- Function: atom? object
     Returns #t if OBJECT is not a pair and #f if it is pair.  (Called atom in Common LISP.)

          (atom? 1)
             => #t
          (atom? '(1 2))
             => #f
          (atom? #(1 2))   ; dubious!
             => #t

 -- Function: type-of object
     Returns a symbol name for the type of OBJECT.

 -- Function: coerce object result-type
     Converts and returns OBJECT of type char, number, string, symbol, list, or vector to RESULT-TYPE (which must be one of these symbols).

Format
======

(require 'format)

Format Interface
----------------

 -- Function: format destination format-string . arguments
     An almost complete implementation of Common LISP format description according to the CL reference book Common LISP from Guy L. Steele, Digital Press.  Backward compatible to most of the available Scheme format implementations.

     Returns #t, #f or a string; has side effect of printing according to FORMAT-STRING.  If DESTINATION is #t, the output is to the current output port and #t is returned.  If DESTINATION is #f, a formatted string is returned as the result of the call.  NEW: If DESTINATION is a string, DESTINATION is regarded as the format string; FORMAT-STRING is then the first argument and the output is returned as a string. If DESTINATION is a number, the output is to the current error port if available by the implementation. Otherwise DESTINATION must be an output port and #t is returned.

     FORMAT-STRING must be a string.  In case of a formatting error format returns #f and prints a message on the current output or error port.  Characters are output as if the string were output by the display function with the exception of those prefixed by a tilde (~).  For a detailed description of the FORMAT-STRING syntax please consult a Common LISP format reference manual.  For a test suite to verify this format implementation load formatst.scm. Please send bug reports to lutzeb@cs.tu-berlin.de.

     Note: format is not reentrant, i.e. only one format-call may be executed at a time.

Format Specification (Format version 3.0)
-----------------------------------------

Please consult a Common LISP format reference manual for a detailed description of the format string syntax.  For a demonstration of the implemented directives see formatst.scm.

This implementation supports directive parameters and modifiers (: and @ characters). Multiple parameters must be separated by a comma (,).  Parameters can be numerical parameters (positive or negative), character parameters (prefixed by a quote character ('), variable parameters (v), number of rest arguments parameter (#), empty and default parameters.  Directive characters are case independent. The general form of a directive is:

DIRECTIVE ::= ~{DIRECTIVE-PARAMETER,}[:][@]DIRECTIVE-CHARACTER

DIRECTIVE-PARAMETER ::= [ [-|+]{0-9}+ | 'CHARACTER | v | # ]

Implemented CL Format Control Directives
........................................

Documentation syntax: Uppercase characters represent the corresponding control directive characters. Lowercase characters represent control directive parameter descriptions.

~A
     Any (print as display does).

     ~@A
          left pad.

     ~MINCOL,COLINC,MINPAD,PADCHARA
          full padding.

~S
     S-expression (print as write does).

     ~@S
          left pad.

     ~MINCOL,COLINC,MINPAD,PADCHARS
          full padding.

~D
     Decimal.

     ~@D
          print number sign always.

     ~:D
          print comma separated.

     ~MINCOL,PADCHAR,COMMACHARD
          padding.

~X
     Hexadecimal.

     ~@X
          print number sign always.

     ~:X
          print comma separated.

     ~MINCOL,PADCHAR,COMMACHARX
          padding.

~O
     Octal.

     ~@O
          print number sign always.

     ~:O
          print comma separated.

     ~MINCOL,PADCHAR,COMMACHARO
          padding.

~B
     Binary.

     ~@B
          print number sign always.

     ~:B
          print comma separated.

     ~MINCOL,PADCHAR,COMMACHARB
          padding.

~NR
     Radix N.

     ~N,MINCOL,PADCHAR,COMMACHARR
          padding.

~@R
     print a number as a Roman numeral.

~:R
     print a number as an ordinal English number.

~:@R
     print a number as a cardinal English number.

~P
     Plural.

     ~@P
          prints y and ies.

     ~:P
          as ~P but jumps 1 argument backward.

     ~:@P
          as ~@P but jumps 1 argument backward.

~C
     Character.

     ~@C
          prints a character as the reader can understand it (i.e. #\ prefixing).

     ~:C
          prints a character as emacs does (eg. ^C for ASCII 03).

~F
     Fixed-format floating-point (prints a flonum like MMM.NNN).

     ~WIDTH,DIGITS,SCALE,OVERFLOWCHAR,PADCHARF

     ~@F
          If the number is positive a plus sign is printed.

~E
     Exponential floating-point (prints a flonum like MMM.NNNEEE).

     ~WIDTH,DIGITS,EXPONENTDIGITS,SCALE,OVERFLOWCHAR,PADCHAR,EXPONENTCHARE

     ~@E
          If the number is positive a plus sign is printed.

~G
     General floating-point (prints a flonum either fixed or exponential).

     ~WIDTH,DIGITS,EXPONENTDIGITS,SCALE,OVERFLOWCHAR,PADCHAR,EXPONENTCHARG

     ~@G
          If the number is positive a plus sign is printed.

~$
     Dollars floating-point (prints a flonum in fixed with signs separated).

     ~DIGITS,SCALE,WIDTH,PADCHAR$

     ~@$
          If the number is positive a plus sign is printed.

     ~:@$
          A sign is always printed and appears before the padding.

     ~:$
          The sign appears before the padding.

~%
     Newline.

     ~N%
          print N newlines.

~&
     print newline if not at the beginning of the output line.

     ~N&
          prints ~& and then N-1 newlines.

~|
     Page Separator.

     ~N|
          print N page separators.

~~
     Tilde.

     ~N~
          print N tildes.

~<newline>
     Continuation Line.

     ~:<newline>
          newline is ignored, white space left.

     ~@<newline>
          newline is left, white space ignored.

~T
     Tabulation.

     ~@T
          relative tabulation.

     ~COLNUM,COLINCT
          full tabulation.

~?
     Indirection (expects indirect arguments as a list).

     ~@?
          extracts indirect arguments from format arguments.

~(STR~)
     Case conversion (converts by string-downcase).

     ~:(STR~)
          converts by string-capitalize.

     ~@(STR~)
          converts by string-capitalize-first.

     ~:@(STR~)
          converts by string-upcase.

~*
     Argument Jumping (jumps 1 argument forward).

     ~N*
          jumps N arguments forward.

     ~:*
          jumps 1 argument backward.

     ~N:*
          jumps N arguments backward.

     ~@*
          jumps to the 0th argument.

     ~N@*
          jumps to the Nth argument (beginning from 0)

~[STR0~;STR1~;...~;STRN~]
     Conditional Expression (numerical clause conditional).

     ~N[
          take argument from N.

     ~@[
          true test conditional.

     ~:[
          if-else-then conditional.

     ~;
          clause separator.

     ~:;
          default clause follows.

~{STR~}
     Iteration (args come from the next argument (a list)).

     ~N{
          at most N iterations.

     ~:{
          args from next arg (a list of lists).

     ~@{
          args from the rest of arguments.

     ~:@{
          args from the rest args (lists).

~^
     Up and out.

     ~N^
          aborts if N = 0

     ~N,M^
          aborts if N = M

     ~N,M,K^
          aborts if N <= M <= K

Not Implemented CL Format Control Directives
............................................

~:A
     print #f as an empty list (see below).

~:S
     print #f as an empty list (see below).

~<~>
     Justification.

~:^
     (sorry I don't understand its semantics completely)

Extended, Replaced and Additional Control Directives
....................................................

~MINCOL,PADCHAR,COMMACHAR,COMMAWIDTHD

~MINCOL,PADCHAR,COMMACHAR,COMMAWIDTHX

~MINCOL,PADCHAR,COMMACHAR,COMMAWIDTHO

~MINCOL,PADCHAR,COMMACHAR,COMMAWIDTHB

~N,MINCOL,PADCHAR,COMMACHAR,COMMAWIDTHR
     COMMAWIDTH is the number of characters between two comma characters.

~I
     print a R4RS complex number as ~F~@Fi with passed parameters for ~F.

~Y
     Pretty print formatting of an argument for scheme code lists.

~K
     Same as ~?.

~!
     Flushes the output if format DESTINATION is a port.

~_
     Print a #\space character

     ~N_
          print N #\space characters.

~/
     Print a #\tab character

     ~N/
          print N #\tab characters.

~NC
     Takes N as an integer representation for a character. No arguments are consumed. N is converted to a character by integer->char.  N must be a positive decimal number.

~:S
     Print out readproof.  Prints out internal objects represented as #<...> as strings "#<...>" so that the format output can always be processed by read.

~:A
     Print out readproof.  Prints out internal objects represented as #<...> as strings "#<...>" so that the format output can always be processed by read.

~Q
     Prints information and a copyright notice on the format implementation.

     ~:Q
          prints format version.

~F, ~E, ~G, ~$
     may also print number strings, i.e. passing a number as a string and format it accordingly.

Configuration Variables
.......................

Format has some configuration variables at the beginning of format.scm to suit the systems and users needs. There should be no modification necessary for the configuration that comes with SLIB. If modification is desired the variable should be set after the format code is loaded. Format detects automatically if the running scheme system implements floating point numbers and complex numbers.

FORMAT:SYMBOL-CASE-CONV
     Symbols are converted by symbol->string so the case type of the printed symbols is implementation dependent. format:symbol-case-conv is a one arg closure which is either #f (no conversion), string-upcase, string-downcase or string-capitalize. (default #f)

FORMAT:IOBJ-CASE-CONV
     As FORMAT:SYMBOL-CASE-CONV but applies for the representation of implementation internal objects. (default #f)

FORMAT:EXPCH
     The character prefixing the exponent value in ~E printing. (default #\E)

Compatibility With Other Format Implementations
...............................................

SLIB format 2.x:
     See format.doc.

SLIB format 1.4:
     Downward compatible except for padding support and ~A, ~S, ~P, ~X uppercase printing.  SLIB format 1.4 uses C-style printf padding support which is completely replaced by the CL format padding style.

MIT C-Scheme 7.1:
     Downward compatible except for ~, which is not documented (ignores all characters inside the format string up to a newline character).  (7.1 implements ~a, ~s, ~NEWLINE, ~~, ~%, numerical and variable parameters and :/@ modifiers in the CL sense).

Elk 1.5/2.0:
     Downward compatible except for ~A and ~S which print in uppercase.  (Elk implements ~a, ~s, ~~, and ~% (no directive parameters or modifiers)).

Scheme->C 01nov91:
     Downward compatible except for an optional destination parameter: S2C accepts a format call without a destination which returns a formatted string. This is equivalent to a #f destination in S2C. (S2C implements ~a, ~s, ~c, ~%, and ~~ (no directive parameters or modifiers)).

This implementation of format is solely useful in the SLIB context because it requires other components provided by SLIB.

Generic-Write
=============

(require 'generic-write)

generic-write is a procedure that transforms a Scheme data value (or Scheme program expression) into its textual representation and prints it.  The interface to the procedure is sufficiently general to easily implement other useful formatting procedures such as pretty printing, output to a string and truncated output.

 -- Procedure: generic-write obj display? width output

     obj
          Scheme data value to transform.

     display?
          Boolean, controls whether characters and strings are quoted.

     width
          Extended boolean, selects format:

          #f
               single line format

          integer > 0
               pretty-print (value = max nb of chars per line)

     output
          Procedure of 1 argument of string type, called repeatedly with successive substrings of the textual representation.  This procedure can return #f to stop the transformation.

     The value returned by generic-write is undefined.

     Examples:

          (write obj) == (generic-write obj #f #f DISPLAY-STRING)
          (display obj) == (generic-write obj #t #f DISPLAY-STRING)

     where

          DISPLAY-STRING ==
          (lambda (s) (for-each write-char (string->list s)) #t)

Line I/O
========

(require 'line-i/o)

 -- Function: read-line
 -- Function: read-line port
     Returns a string of the characters up to, but not including a newline or end of file, updating PORT to point to the character following the newline.  If no characters are available, an end of file object is returned.  PORT may be omitted, in which case it defaults to the value returned by current-input-port.

 -- Function: read-line! string
 -- Function: read-line! string port
     Fills STRING with characters up to, but not including a newline or end of file, updating the port to point to the last character read or following the newline if it was read.  If no characters are available, an end of file object is returned.  If a newline or end of file was found, the number of characters read is returned.  Otherwise, #f is returned.  PORT may be omitted, in which case it defaults to the value returned by current-input-port.

 -- Function: write-line string
 -- Function: write-line string port
     Writes STRING followed by a newline to the given port and returns an unspecified value.  Port may be omited, in which case it defaults to the value returned by current-input-port.

Multi-Processing
================

(require 'process)

 -- Procedure: add-process! proc
     Adds proc, which must be a procedure (or continuation) capable of accepting accepting one argument, to the process:queue.  The value returned is unspecified.  The argument to PROC should be ignored.  If PROC returns, the process is killed.

 -- Procedure: process:schedule!
     Saves the current process on process:queue and runs the next process from process:queue.  The value returned is unspecified.

 -- Procedure: kill-process!
     Kills the current process and runs the next process from process:queue.  If there are no more processes on process:queue, (slib:exit) is called (see System).

Object-To-String
================

(require 'object->string)

 -- Function: object->string obj
     Returns the textual representation of OBJ as a string.

Pretty-Print
============

(require 'pretty-print)

 -- Procedure: pretty-print obj
 -- Procedure: pretty-print obj port

     pretty-prints OBJ on PORT.  If PORT is not specified, current-output-port is used.

     Example:

          (pretty-print '((1 2 3 4 5) (6 7 8 9 10) (11 12 13 14 15)
                          (16 17 18 19 20) (21 22 23 24 25)))
             -| ((1 2 3 4 5)
             -|  (6 7 8 9 10)
             -|  (11 12 13 14 15)
             -|  (16 17 18 19 20)
             -|  (21 22 23 24 25))

(require 'pprint-file)

 -- Procedure: pprint-file infile
 -- Procedure: pprint-file infile outfile
     Pretty-prints all the code in INFILE.  If OUTFILE is specified, the output goes to OUTFILE, otherwise it goes to (current-output-port).

 -- Function: pprint-filter-file infile proc outfile
 -- Function: pprint-filter-file infile proc
     INFILE is a port or a string naming an existing file.  Scheme source code expressions and definitions are read from the port (or file) and PROC is applied to them sequentially.

     OUTFILE is a port or a string.  If no OUTFILE is specified then current-output-port is assumed.  These expanded expressions are then pretty-printed to this port.

     Whitepsace and comments (introduced by ;) which are not part of scheme expressions are reproduced in the output.  This procedure does not affect the values returned by current-input-port and current-output-port.

pprint-filter-file can be used to pre-compile macro-expansion and thus can reduce loading time.  The following will write into exp-code.scm the result of expanding all defmacros in code.scm.

     (require 'pprint-file)
     (require 'defmacroexpand)
     (defmacro:load "my-macros.scm")
     (pprint-filter-file "code.scm" defmacro:expand* "exp-code.scm")

Sorting
=======

(require 'sort)

Many Scheme systems provide some kind of sorting functions.  They do not, however, always provide the same sorting functions, and those that I have had the opportunity to test provided inefficient ones (a common blunder is to use quicksort which does not perform well).

Because sort and sort! are not in the standard, there is very little agreement about what these functions look like.  For example, Dybvig says that Chez Scheme provides

     (merge predicate list1 list2)
     (merge! predicate list1 list2)
     (sort predicate list)
     (sort! predicate list)

while MIT Scheme 7.1, following Common LISP, offers unstable

     (sort list predicate)

TI PC Scheme offers

     (sort! list/vector predicate?)

and Elk offers

     (sort list/vector predicate?)
     (sort! list/vector predicate?)

Here is a comprehensive catalogue of the variations I have found.

 1. Both sort and sort! may be provided.

 2. sort may be provided without sort!.

 3. sort! may be provided without sort.

 4. Neither may be provided.

 5. The sequence argument may be either a list or a vector.

 6. The sequence argument may only be a list.

 7. The sequence argument may only be a vector.

 8. The comparison function may be expected to behave like <.

 9. The comparison function may be expected to behave like <=.

 10. The interface may be (sort predicate? sequence).

 11. The interface may be (sort sequence predicate?).

 12. The interface may be (sort sequence &optional (predicate? <)).

 13. The sort may be stable.

 14. The sort may be unstable.

All of this variation really does not help anybody.  A nice simple merge sort is both stable and fast (quite a lot faster than `quick' sort).

I am providing this source code with no restrictions at all on its use (but please retain D.H.D.Warren's credit for the original idea).  You may have to rename some of these functions in order to use them in a system which already provides incompatible or inferior sorts.  For each of the functions, only the top-level define needs to be edited to do that.

I could have given these functions names which would not clash with any Scheme that I know of, but I would like to encourage implementors to converge on a single interface, and this may serve as a hint.  The argument order for all functions has been chosen to be as close to Common LISP as made sense, in order to avoid NIH-itis.

Each of the five functions has a required last parameter which is a comparison function.  A comparison function f is a function of 2 arguments which acts like <.  For example,

     (not (f x x))
     (and (f x y) (f y z)) == (f x z)

The standard functions <, >, char<?, char>?, char-ci<?, char-ci>?, string<?, string>?, string-ci<?, and string-ci>? are suitable for use as comparison functions.  Think of (less? x y) as saying when x must not precede y.

 -- Function: sorted? sequence less?
     Returns #t when the sequence argument is in non-decreasing order according to LESS? (that is, there is no adjacent pair ... x y ... for which (less? y x)).

     Returns #f when the sequence contains at least one out-of-order pair.  It is an error if the sequence is neither a list nor a vector.

 -- Function: merge list1 list2 less?
     This merges two lists, producing a completely new list as result.  I gave serious consideration to producing a Common-LISP-compatible version.  However, Common LISP's sort is our sort! (well, in fact Common LISP's stable-sort is our sort!, merge sort is fast as well as stable!) so adapting CL code to Scheme takes a bit of work anyway.  I did, however, appeal to CL to determine the order of the arguments.

 -- Procedure: merge! list1 list2 less?
     Merges two lists, re-using the pairs of LIST1 and LIST2 to build the result.  If the code is compiled, and LESS? constructs no new pairs, no pairs at all will be allocated.  The first pair of the result will be either the first pair of LIST1 or the first pair of LIST2, but you can't predict which.

     The code of merge and merge! could have been quite a bit simpler, but they have been coded to reduce the amount of work done per iteration.  (For example, we only have one null? test per iteration.)

 -- Function: sort sequence less?
     Accepts either a list or a vector, and returns a new sequence which is sorted.  The new sequence is the same type as the input.  Always (sorted? (sort sequence less?) less?).  The original sequence is not altered in any way.  The new sequence shares its elements with the old one; no elements are copied.

 -- Procedure: sort! sequence less?
     Returns its sorted result in the original boxes.  If the original sequence is a list, no new storage is allocated at all.  If the original sequence is a vector, the sorted elements are put back in the same vector.

     Some people have been confused about how to use sort!, thinking that it doesn't return a value.  It needs to be pointed out that

          (set! slist (sort! slist <))

     is the proper usage, not

          (sort! slist <)

Note that these functions do not accept a CL-style :key argument.  A simple device for obtaining the same expressiveness is to define

     (define (keyed less? key)
       (lambda (x y) (less? (key x) (key y))))

and then, when you would have written

     (sort a-sequence #'my-less :key #'my-key)

in Common LISP, just write

     (sort! a-sequence (keyed my-less? my-key))

in Scheme.

Standard I/O
============

(require 'stdio)

 -- Procedure: printf format . args
 -- Procedure: fprintf port format . args
 -- Procedure: sprintf str format . args

Note: Floating-point output is not handled yet.

 -- Variable: stdin
     Defined to be (current-input-port).

 -- Variable: stdout
     Defined to be (current-output-port).

 -- Variable: stderr
     Defined to be (current-error-port).

 -- Function: scanf format . args
 -- Function: fscanf port format . args
 -- Function: sscanf str format . args

     Each function reads characters, interprets them according to the control string FORMAT argument, and returns a list of the items specified. ARGS are ignored; they are allowed for compatability with the C function of the same name.  The control string contains conversion specifications and other characters used to direct interpretation of input sequences.  The control string contains:

       * White-space characters (blanks, tabs, newlines, or formfeeds) that cause input to be read up to the next non-white-space character (except in cases described below).

       * An ordinary character (not %) that must match the next character of the input stream.

       * Conversion specifications, consisting of the character %, an optional assignment suppressing character *, an optional numerical maximum-field width, an optional l (ell), h or L which is ignored, and a conversion code.

     A conversion specification directs the conversion of the next input field.  The result of a conversion specification is returned in the position of the corresponding argument points, unless * indicates assignment suppression.  Assignment suppression provides a way to describe an input field to be skipped.  An input field is defined as a string of non-space characters; it extends to the next inappropriate character or until the field width, if specified, is exhausted.  For all descriptors except c, white space leading an input field is ignored.

     The conversion code indicates the interpretation of the input field; For a suppressed field, no value is returned.  The following conversion codes are legal:

     %
          A single % is expected in the input at this point; no value is returned.

     d
          A decimal integer is expected.

     o
          An octal integer is expected.

     x
          A hexadecimal integer is expected.

     f
          A floating-point number is expected.  The input format for floating-point numbers is an optionally signed string of digits, possibly containing a radix character, followed by an optional exponent field consisting of an E or an e, followed by an optional +, -, or space, followed by an integer.

     c
          A character is expected.  The normal skip-over-white-space is suppressed in this case; to read the next non-space character, use %1s.  If a field width is given, a string is returned; the indicated number of characters is read.

     s
     S
          A character string is expected The input field is terminated by a white-space character.  scanf cannot read a null string.

     The l, L and h modifiers are ignored.

     The scanf functions terminate their conversions at end-of-file, at the end of the control string, or when an input character conflicts with the control string.  In the latter case, the offending character is left unread in the input stream.

String-Case
===========

(require 'string-case)

 -- Procedure: string-upcase str
 -- Procedure: string-downcase str
 -- Procedure: string-capitalize str
     The obvious string conversion routines.  These are non-destructive.

 -- Function: string-upcase! str
 -- Function: string-downcase! str
 -- Function: string-captialize! str
     The destructive versions of the functions above.

String Ports
============

(require 'string-port)

 -- Procedure: call-with-output-string proc
     PROC must be a procedure of one argument.  This procedure calls PROC with one argument: a (newly created) output port.  When the function returns, the string composed of the characters written into the port is returned.

 -- Procedure: call-with-input-string string proc
     PROC must be a procedure of one argument.  This procedure calls PROC with one argument: an (newly created) input port from which STRING's contents may be read.  When PROC returns, the port is closed and the value yielded by the procedure PROC is returned.

Tektronix Graphics Support
==========================

Note: The Tektronix graphics support files need more work, and are not complete.

Tektronix 4000 Series Graphics
------------------------------

The Tektronix 4000 series graphics protocol gives the user a 1024 by 1024 square drawing area.  The origin is in the lower left corner of the screen.  Increasing y is up and increasing x is to the right.

The graphics control codes are sent over the current-output-port and can be mixed with regular text and ANSI or other terminal control sequences.

 -- Procedure: tek40:init

 -- Procedure: tek40:graphics

 -- Procedure: tek40:text

 -- Procedure: tek40:linetype linetype

 -- Procedure: tek40:move x y

 -- Procedure: tek40:draw x y

 -- Procedure: tek40:put-text x y str

 -- Procedure: tek40:reset

Tektronix 4100 Series Graphics
------------------------------

The graphics control codes are sent over the current-output-port and can be mixed with regular text and ANSI or other terminal control sequences.

 -- Procedure: tek41:init

 -- Procedure: tek41:reset

 -- Procedure: tek41:graphics

 -- Procedure: tek41:move x y

 -- Procedure: tek41:draw x y

 -- Procedure: tek41:point x y number

 -- Procedure: tek41:encode-x-y x y

 -- Procedure: tek41:encode-int number

Tree operations
===============

(require 'tree)

These are operations that treat lists a representations of trees.

 -- Function: subst new old tree
 -- Function: substq new old tree
 -- Function: substv new old tree
     subst makes a copy of TREE, substituting NEW for every subtree or leaf of TREE which is equal? to OLD and returns a modified tree.  The original TREE is unchanged, but may share parts with the result.

     substq and substv are similar, but test against OLD using eq? and eqv? respectively.

     Examples:

          (substq 'tempest 'hurricane '(shakespeare wrote (the hurricane)))
             => (shakespeare wrote (the tempest))
          (substq 'foo '() '(shakespeare wrote (twelfth night)))
             => (shakespeare wrote (twelfth night . foo) . foo)
          (subst '(a . cons) '(old . pair)
                 '((old . spice) ((old . shoes) old . pair) (old . pair)))
             => ((old . spice) ((old . shoes) a . cons) (a . cons))

 -- Function: copy-tree tree
     Makes a copy of the nested list structure TREE using new pairs and returns it.  All levels are copied, so that none of the pairs in the tree are eq? to the original ones -- only the leaves are.

     Example:

          (define bar '(bar))
          (copy-tree (list bar 'foo))
             => ((bar) foo)
          (eq? bar (car (copy-tree (list bar 'foo))))
             => #f

Standards Support
*****************

With-File
=========

(require 'with-file)

 -- Function: with-input-from-file file thunk
 -- Function: with-output-to-file file thunk
     Description found in R4RS.

Transcripts
===========

(require 'transcript)

 -- Function: transcript-on filename
 -- Function: transcript-off filename
     Redefines read-char, read, write-char, write, display, and newline.

Rev2 Procedures
===============

(require 'rev2-procedures)

The procedures below were specified in the Revised^2 Report on Scheme.  N.B.: The symbols 1+ and -1+ are not R4RS syntax.  Scheme->C, for instance, barfs on this module.

 -- Procedure: substring-move-left! string1 start1 end1 string2 start2
 -- Procedure: substring-move-right! string1 start1 end1 string2 start2
     STRING1 and STRING2 must be a strings, and START1, START2 and END1 must be exact integers satisfying

          0 <= START1 <= END1 <= (string-length STRING1)
          0 <= START2 <= END1 - START1 + START2 <= (string-length STRING2)

     substring-move-left! and substring-move-right! store characters of STRING1 beginning with index START1 (inclusive) and ending with index END1 (exclusive) into STRING2 beginning with index START2 (inclusive).

     substring-move-left! stores characters in time order of increasing indices.  substring-move-right! stores characters in time order of increasing indeces.

 -- Procedure: substring-fill! string start end char
     Fills the elements START--END of STRING with the character CHAR.

 -- Function: string-null? str
     == (= 0 (string-length STR))

 -- Procedure: append! . pairs
     Destructively appends its arguments.  Equivalent to nconc.

 -- Function: 1+ n
     Adds 1 to N.

 -- Function: -1+ n
     Subtracts 1 from N.

 -- Function: <?
 -- Function: <=?
 -- Function: >?
 -- Function: >=?
     These are equivalent to the procedures of the same name but without the trailing ?.

 -- Function: last-pair l
     Returns the last pair in the list L.  Example:

          (last-pair (cons 1 2))
             => (1 . 2)
          (last-pair '(1 2))
             => (2)
              == (cons 2 '())

 -- Variable: t
     Derfined as #t.

 -- Variable: nil
     Defined as #f.

Rev4 Optional Procedures
========================

(require 'rev4-optional-procedures)

For the specification of these optional procedures, see Standard procedures (Revised(4) Scheme).

 -- Function: list-tail l p

 -- Function: string->list s

 -- Function: list->string l

 -- Function: string-copy

 -- Procedure: string-fill! s obj

 -- Function: list->vector l

 -- Function: vector->list s

 -- Procedure: vector-fill! s obj

Multi-argument / and -
======================

(require 'mutliarg/and-)

For the specification of these optional forms, see Numerical operations (Revised(4) Scheme).  The two-arg:* forms are only defined if the implementation does not support the many-argument forms.

 -- Function: two-arg:/ n1 n2
     The original two-argument version of /.

 -- Function: / divident . divisors

 -- Function: two-arg:- n1 n2
     The original two-argument version of -.

 -- Function: - minuend . subtrahends

Multi-argument Apply
====================

(require 'multiarg-apply)

For the specification of this optional form, see Control features (Revised(4) Scheme).

 -- Function: two-arg:apply proc l
     The implementation's native apply.  Only defined for implementations which don't support the many-argument version.

 -- Function: apply proc . args

Rationalize
===========

(require 'rationalize)

The procedure rationalize is interesting because most programming languages do not provide anything analogous to it.  For simplicity, we present an algorithm which computes the correct result for exact arguments (provided the implementation supports exact rational numbers of unlimited precision), and produces a reasonable answer for inexact arguments when inexact arithmetic is implemented using floating-point. We thank Alan Bawden for contributing this algorithm.

 -- Function: rationalize x e

Promises
========

(require 'promise)

 -- Function: make-promise proc

Change occurrences of (delay EXPRESSION) to (make-promise (lambda () EXPRESSION)) and (define force promise:force) to implement promises if your implementation doesn't support them (see Control features (Revised(4) Scheme)).

Dynamic-Wind
============

(require 'dynamic-wind)

This facility is a generalization of Common LISP unwind-protect, designed to take into account the fact that continuations produced by call-with-current-continuation may be reentered.

 -- Procedure: dynamic-wind thunk1 thunk2 thunk3
     The arguments THUNK1, THUNK2, and THUNK3 must all be procedures of no arguments (thunks).

     dynamic-wind calls THUNK1, THUNK2, and then THUNK3.  The value returned by THUNK2 is returned as the result of dynamic-wind.  THUNK3 is also called just before control leaves the dynamic context of THUNK2 by calling a continuation created outside that context.  Furthermore, THUNK1 is called before reentering the dynamic context of THUNK2 by calling a continuation created inside that context.  (Control is inside the context of THUNK2 if THUNK2 is on the current return stack).

     Warning: There is no provision for dealing with errors or interrupts.  If an error or interrupt occurs while using dynamic-wind, the dynamic environment will be that in effect at the time of the error or interrupt.

Values
======

(require 'values)

 -- Function: values obj ...
     values takes any number of arguments, and passes (returns) them to its continuation.

 -- Function: call-with-values thunk proc
     THUNK must be a procedure of no arguments, and PROC must be a procedure.  call-with-values calls THUNK with a continuation that, when passed some values, calls PROC with those values as arguments.

     Except for continuations created by the call-with-values procedure, all continuations take exactly one value, as now; the effect of passing no value or more than one value to continuations that were not created by the call-with-values procedure is unspecified.

Time
====

The procedures current-time, difftime, and offset-time are supported by all implementations (SLIB provides them if feature ('current-time) is missing.  current-time returns a calendar time (caltime) which can be a number or other type.

 -- Function: current-time
     Returns the time since 00:00:00 GMT, January 1, 1970, measured in seconds.  Note that the reference time is different from the reference time for get-universal-time in CLTime.  On implementations which cannot support actual times, current-time will increment a counter and return its value when called.

 -- Function: difftime caltime1 caltime0
     Returns the difference (number of seconds) between twe calendar times: CALTIME1 - CALTIME0.  CALTIME0 can also be a number.

 -- Function: offset-time caltime offset
     Returns the calendar time of CALTIME offset by OFFSET number of seconds (+ caltime offset).

     (require 'posix-time)

These procedures are intended to be compatible with Posix time conversion functions.

 -- Variable: *timezone*
     contains the difference, in seconds, between UTC and local standard time (for example, in the U.S.  Eastern time zone (EST), timezone is 5*60*60).  *timezone* is initialized by tzset.

 -- Function: tzset
     initializes the *TIMEZONE* variable from the TZ environment variable.  This function is automatically called by the other time conversion functions that depend on the time zone.

 -- Function: gmtime caltime
     converts the calendar time CALTIME to a vector of integers representing the time expressed as Coordinated Universal Time (UTC).

 -- Function: localtime caltime
     converts the calendar time CALTIME to a vector of integers expressed relative to the user's time zone.  localtime sets the variable *TIMEZONE* with the difference between Coordinated Universal Time (UTC) and local standard time in seconds by calling tzset. The elements of the returned vector are as follows:

      0. seconds (0 - 61)

      1. minutes (0 - 59)

      2. hours since midnight

      3. day of month

      4. month (0 - 11).  Note difference from decode-universal-time.

      5. year (A.D.)

      6. day of week (0 - 6)

      7. day of year (0 - 365)

      8. 1 for daylight savings, 0 for regular time

 -- Function: mktime univtime
     Converts a vector of integers in Coordinated Universal Time (UTC) format to calendar time (caltime) format.

 -- Function: asctime univtime
     Converts the vector of integers CALTIME in Coordinated Universal Time (UTC) format into a string of the form "Wed Jun 30 21:49:08 1993".

 -- Function: ctime caltime
     Equivalent to (time:asctime (time:localtime CALTIME)).

CLTime
======

 -- Function: get-decoded-time
     Equivalent to (decode-universal-time (get-universal-time)).

 -- Function: get-universal-time
     Returns the current time as Universal Time, number of seconds since 00:00:00 Jan 1, 1900 GMT.  Note that the reference time is different from current-time.

 -- Function: decode-universal-time univtime
     Converts UNIVTIME to Decoded Time format. Nine values are returned:

      0. seconds (0 - 61)

      1. minutes (0 - 59)

      2. hours since midnight

      3. day of month

      4. month (1 - 12).  Note difference from gmtime and localtime.

      5. year (A.D.)

      6. day of week (0 - 6)

      7. #t for daylight savings, #f otherwise

      8. hours west of GMT (-24 - +24)

     Notice that the values returned by decode-universal-time do not match the arguments to encode-universal-time.

 -- Function: encode-universal-time second minute hour date month year
 -- Function: encode-universal-time second minute hour date month year time-zone
     Converts the arguments in Decoded Time format to Universal Time format. If TIME-ZONE is not specified, the returned time is adjusted for daylight saving time.  Otherwise, no adjustment is performed.

     Notice that the values returned by decode-universal-time do not match the arguments to encode-universal-time.

Session Support
***************

Repl
====

(require 'repl)

Here is a read-eval-print-loop which, given an eval, evaluates forms.

 -- Procedure: repl:top-level repl:eval
     reads, repl:evals and writes expressions from (current-input-port) to (current-output-port) until an end-of-file is encountered.  load, slib:eval, slib:error, and repl:quit dynamically bound during repl:top-level.

 -- Procedure: repl:quit
     Exits from the invocation of repl:top-level.

The repl: procedures establish, as much as is possible to do portably, a top level environment supporting macros. repl:top-level uses dynamic-wind to catch error conditions and interrupts.  If your implementation supports this you are all set.

Otherwise, if there is some way your implementation can catch error conditions and interrupts, then have them call slib:error.  It will display its arguments and reenter repl:top-level. slib:error dynamically bound by repl:top-level.

To have your top level loop always use macros, add any interrupt catching lines and the following lines to your Scheme init file:

     (require 'macro)
     (require 'repl)
     (repl:top-level macro:eval)

Debug
=====

(require 'debug)

 -- Procedure: print args
     Print writes all its arguments, separated by spaces.  Print outputs a newline at the end and returns the value of the last argument.  Note that print is also defined in the yasos module (see Yasos).

 -- Procedure: qp args
 -- Procedure: qpn args
 -- Procedure: qpr args
     qp writes its arguments, separated by spaces, to (current-output-port).  qp compresses printing by substituting ... for substructure it does not have sufficient room to print.  qpn is like qp but outputs a newline before returning.  qpr is like qpn except that it returns its last argument.

 -- Variable: *qp-width*
     *qp-width* is the largest number of characters that qp uses.

 -- Procedure: trace-all file
     Traces (see Trace) all procedures defined at top-level in file file.

Breakpoints
-----------

 -- Function: init-debug
     Typing (init-debug) at top level sets up a continuation for break.

 -- Function: break arg1 ...
     Returns from the top level continuation and pushes the continuation from which it was called on debug:break-continuation-stack.

 -- Function: continue
     Pops the topmost continuation off of debug:break-continuation-stack and returns #f to it.

Tracing
=======

(require 'trace)

 -- Macro: trace proc1 ...
     Traces the top-level named procedures given as arguments.
 -- Macro: trace
     With no arguments, makes sure that all the currently traced identifiers are traced (even if those identifiers have been redefined) and returns a list of the traced identifiers.

 -- Macro: untrace proc1 ...
     Turns tracing off for its arguments.
 -- Macro: untrace
     With no arguments, untraces all currently traced identifiers and returns a list of these formerly traced identifiers.

The following routines are the procedures which actually do the tracing when this module is supplied by SLIB, rather than natively.  If macros are not natively supported by your implementation, these might be more convenient to use.

 -- Function: tracef
 -- Function: debug:tracef
     To trace, type

          (set! SYMBOL (tracef SYMBOL))

     or

          (set! SYMBOL (tracef SYMBOL 'SYMBOL))

     or

          (define SYMBOL (tracef FUNCTION))

     or

          (define SYMBOL (tracef FUNCTION 'SYMBOL))

 -- Function: untracef
 -- Function: debug:untracef function
     To untrace, type

          (set! SYMBOL (untracef SYMBOL))

Test
====

(require 'test)

 -- Function: test expected fun . args
     Compares EXPECTED to the result of applying FUN to ARGS.  If they are not equal? then prints an error message. An unspecified value is returned.

 -- Function: report-errs
     Prints a summary of all error encountered by test.  An unspecified value is returned.

Getopt
======

(require 'getopt)

This routine implements Posix command line argument parsing.  Notice that returning values through global variables means that getopt is not reentrant.

 -- Variable: *optind*
     Is the index of the current element of the command line.  It is initially one.  In order to parse a new command line or reparse an old one, *OPTING* must be reset.

 -- Variable: *optarg*
     Is set by getopt to the (string) option-argument of the current option.

 -- Procedure: getopt argc argv optstring
     Returns the next option letter in ARGV (starting from (vector-ref argv *optind*)) that matches a letter in OPTSTRING.  ARGV is a vector or list of strings, the 0th of which getopt usually ignores. ARGC is the argument count, usually the length of ARGV.  OPTSTRING is a string of recognized option characters; if a character is followed by a colon, the option takes an argument which may be immediately following it in the string or in the next element of ARGV.

     *OPTIND* is the index of the next element of the ARGV vector to be processed.  It is initialized to 1 by getopt.scm, and getopt updates it when it finishes with each element of ARGV.

     getopt returns the next option character from ARGV that matches a character in OPTSTRING, if there is one that matches. If the option takes an argument, getopt sets the variable *OPTARG* to the option-argument as follows:

       * If the option was the last character in the string pointed to by an element of ARGV, then *OPTARG* contains the next element of ARGV, and *OPTIND* is incremented by 2.  If the resulting value of *OPTIND* is greater than or equal to ARGC, this indicates a missing option argument, and getopt returns an error indication.

       * Otherwise, *OPTARG* is set to the string following the option character in that element of ARGV, and *OPTIND* is incremented by 1.

     If, when getopt is called, the string (vector-ref argv *optind*) either does not begin with the character #\- or is just "-", getopt returns #f without changing *OPTIND*.  If (vector-ref argv *optind*) is the string "--", getopt returns #f after incrementing *OPTIND*.

     If getopt encounters an option character that is not contained in OPTSTRING, it returns the question-mark #\? character.  If it detects a missing option argument, it returns the colon character #\: if the first character of OPTSTRING was a colon, or a question-mark character otherwise.  In either case, getopt sets the variable GETOPT:OPT to the option character that caused the error.

     The special option "--" can be used to delimit the end of the options; #f is returned, and "--" is skipped.

     RETURN VALUE

     getopt returns the next option character specified on the command line.  A colon #\: is returned if getopt detects a missing argument and the first character of OPTSTRING was a colon #\:.

     A question-mark #\? is returned if getopt encounters an option character not in OPTSTRING or detects a missing argument and the first character of OPTSTRING was not a colon #\:.

     Otherwise, getopt returns #f when all command line options have been parsed.

     Example:

          #! /usr/local/bin/scm
          ;;;This code is SCM specific.
          (define argv (program-arguments))
          (require 'getopt.scm)
          (require 'debug)

          (define opts ":a:b:cd")
          (let loop ((opt (getopt (length argv) argv opts)))
            (case opt
              ((#\a) (print "option a: " *optarg*))
              ((#\b) (print "option b: " *optarg*))
              ((#\c) (print "option c"))
              ((#\d) (print "option d"))
              ((#\?) (print "error" getopt:opt))
              ((#\:) (print "missing arg" getopt:opt))
              ((#f) (if (< *optind* (length argv))
                        (print "argv[" *optind* "]="
                               (list-ref argv *optind*)))
                    (set! *optind* (+ *optind* 1))))
            (if (< *optind* (length argv))
                (loop (getopt (length argv) argv opts))))

          (slib:exit)

Getopt--
========

 -- Function: getopt-- argc argv optstring
     The procedure getopt-- is an extended version of getopt which parses long option names of the form --hold-the-onions and --verbosity-level=extreme. Getopt-- behaves as getopt except for non-empty options beginning with --.

     Options beginning with -- are returned as strings rather than characters.  If a value is assigned (using =) to a long option, *optarg* is set to the value.  The = and value are not returned as part of the option string.

     No information is passed to getopt-- concerning which long options should be accepted or whether such options can take arguments. If a long option did not have an argument, *optarg will be set to #f.  The caller is responsible for detecting and reporting errors.

          (define opts ":-:b:")
          (define argc 5)
          (define argv '("foo" "-b9" "--f1" "--2=" "--g3=35234.342" "--"))
          (define *optind* 1)
          (define *optarg* #f)
          (require 'debug)
          (do ((i 5 (+ -1 i)))
              ((zero? i))
            (define opt (getopt-- argc argv opts))
            (print *optind* opt *optarg*)))
          -|
          2 #\b "9"
          3 "f1" #f
          4 "2" ""
          5 "g3" "35234.342"
          5 #f "35234.342"

Command Line
============

(require 'read-command)

 -- Function: read-command port
 -- Function: read-command
     read-command converts a command line into a list of strings suitable for parsing by getopt.  The syntax of command lines supported resembles that of popular shells.  read-command updates PORT to point to the first character past the command delimiter.

     If an end of file is encountered in the input before any characters are found that can begin an object or comment, then an end of file object is returned.

     The PORT argument may be omitted, in which case it defaults to the value returned by current-input-port.

     The fields into which the command line is split are delimited by whitespace as defined by char-whitespace?.  The end of a command is delimited by end-of-file or unescaped semicolon (;) or newline.  Any character can be literally included in a field by escaping it with a backslach (\).

     The initial character and types of fields recognized are:

     \
          The next character has is taken literally and not interpreted as a field delimiter.  If \ is the last character before a newline, that newline is just ignored.  Processing continues from the characters after the newline as though the backslash and newline were not there.

     "
          The characters up to the next unescaped " are taken literally, according to [R4RS] rules for literal strings (see Strings (Revised(4) Scheme)).

     (
     '
          One scheme expression is read starting with this character.  The read expression is evaluated, converted to a string (using display), and replaces the expression in the returned field.

     ;
          Semicolon delimits a command.  Using semicolons more than one command can appear on a line.  Escaped semicolons and semicolons inside strings do not delimit commands.

     The comment field differs from the previous fields in that it must be the first character of a command or appear after whitespace in order to be recognized.  # can be part of fields if these conditions are not met.  For instance, ab#c is just the field ab#c.

     #
          Introduces a comment.  The comment continues to the end of the line on which the semicolon appears.  Comments are treated as whitespace by read-dommand-line and backslashes before newlines in comments are also ignored.

System Interface
================

If (provided? 'getenv):

 -- Function: getenv name
     Looks up NAME, a string, in the program environment.  If NAME is found a string of its value is returned.  Otherwise, #f is returned.

If (provided? 'system):

 -- Function: system command-string
     Executes the COMMAND-STRING on the computer and returns the integer status code.

Require
=======

These variables and procedures are provided by all implementations.

 -- Variable: *features*
     Is a list of symbols denoting features supported in this implementation.

 -- Variable: *modules*
     Is a list of pathnames denoting files which have been loaded.

 -- Variable: *catalog*
     Is an association list of features (symbols) and pathnames which will supply those features.  The pathname can be either a string or a pair. If pathname is a pair then the first element should be a macro feature symbol, source, or compiled.  The cdr of the pathname should be either a string or a list.

In the following three functions if FEATURE is not a symbol it is assumed to be a pathname.

 -- Function: provided? feature
     Returns #t if FEATURE is a member of *features* or *modules* or if FEATURE is supported by a file already loaded and #f otherwise.

 -- Procedure: require feature
     If (not (provided? FEATURE)) it is loaded if FEATURE is a pathname or if (assq FEATURE *catalog*).  Otherwise an error is signaled.

 -- Procedure: provide feature
     Assures that FEATURE is contained in *features* if FEATURE is a symbol and *modules* otherwise.

 -- Function: require:feature->path feature
     Returns #t if FEATURE is a member of *features* or *modules* or if FEATURE is supported by a file already loaded.  Returns a path if one was found in *catalog* under the feature name, and #f otherwise.  The path can either be a string suitable as an argument to load or a pair as described above for *catalog*.

Below is a list of features that are automatically determined by require.  For each item, (provided? 'FEATURE) will return #t if that feature is available, and #f if not.

  * 'inexact

  * 'rational

  * 'real

  * 'complex

  * 'bignum

Vicinity
========

A vicinity is a descriptor for a place in the file system.  Vicinities hide from the programmer the concepts of host, volume, directory, and version.  Vicinities express only the concept of a file environment where a file name can be resolved to a file in a system independent manner.  Vicinities can even be used on `flat' file systems (which have no directory structure) by having the vicinity express constraints on the file name.  On most systems a vicinity would be a string.  All of these procedures are file system dependent.

These procedures are provided by all implementations.

 -- Function: make-vicinity filename
     Returns the vicinity of FILENAME for use by in-vicinity.

 -- Function: program-vicinity
     Returns the vicinity of the currently loading Scheme code.  For an interpreter this would be the directory containing source code.  For a compiled system (with multiple files) this would be the directory where the object or executable files are.  If no file is currently loading it the result is undefined.  Warning: program-vicinity can return incorrectl values if your program escapes back into a load.

 -- Function: library-vicinity
     Returns the vicinity of the shared Scheme library.

 -- Function: implementation-vicinity
     Returns the vicinity of the underlying Scheme implementation.  This vicinity will likely contain startup code and messages and a compiler.

 -- Function: user-vicinity
     Returns the vicinity of the current directory of the user.  On most systems this is "" (the empty string).

 -- Function: in-vicinity vicinity filename
     Returns a filename suitable for use by slib:load, slib:load-source, slib:load-compiled, open-input-file, open-output-file, etc.  The returned filename is FILENAME in VICINITY.  in-vicinity should allow FILENAME to override VICINITY when FILENAME is an absolute pathname and VICINITY is equal to the value of (user-vicinity).  The behavior of in-vicinity when FILENAME is absolute and VICINITY is not equal to the value of (user-vicinity) is unspecified.  For most systems in-vicinity can be string-append.

 -- Function: sub-vicinity vicinity name
     Returns the vicinity of VICINITY restricted to NAME.  This is used for large systems where names of files in subsystems could conflict.  On systems with directory structure sub-vicinity will return a pathname of the subdirectory NAME of VICINITY.

Configuration
=============

These constants and procedures describe characteristics of the Scheme and underlying operating system.  They are provided by all implementations.

 -- Constant: char-code-limit
     An integer 1 larger that the largest value which can be returned by char->integer.

 -- Constant: most-positive-fixnum
     The immediate integer closest to positive infinity.

 -- Constant: slib:tab
     The tab character.

 -- Constant: slib:form-feed
     The form-feed character.

 -- Function: software-type
     Returns a symbol denoting the generic operating system type.  For instance, unix, vms, macos, amiga, or ms-dos.

 -- Function: slib:report-version
     Displays the versions of SLIB and the underlying Scheme implementation and the name of the operating system.  An unspecified value is returned.

          (slib:report-version) => slib "2a3" on scm "4e1" on unix

 -- Function: slib:report
     Displays the information of (slib:report-version) followed by almost all the information neccessary for submitting a problem report. An unspecified value is returned.

 -- Function: slib:report #t
     provides a more verbose listing.

 -- Function: slib:report filename
     Writes the report to file filename.

          (slib:report)
          =>
          slib "2a3" on scm "4e1" on unix
          (implementation-vicinity) is "/usr/local/src/scm/"
          (library-vicinity) is "/usr/local/lib/slib/"
          (scheme-file-suffix) is ".scm"
          implementation *features* :
                  bignum complex real rational
                  inexact vicinity ed getenv
                  tmpnam system abort transcript
                  with-file ieee-p1178 rev4-report rev4-optional-procedures
                  hash object-hash delay eval
                  dynamic-wind multiarg-apply multiarg/and- logical
                  defmacro string-port source array-for-each
                  array full-continuation char-ready? line-i/o
                  i/o-extensions pipe
          implementation *catalog* :
                  (rev4-optional-procedures . "/usr/local/lib/slib/sc4opt")
                  ...

Input/Output
============

These procedures are provided by all implementations.

 -- Procedure: file-exists? filename
     Returns #t if the specified file exists.  Otherwise, returns #f.  If the underlying implementation does not support this feature then #f is always returned.

 -- Procedure: delete-file filename
     Deletes the file specified by FILENAME.  If FILENAME can not be deleted, #f is returned.  Otherwise, #t is returned.

 -- Procedure: tmpnam
     Returns a pathname for a file which will likely not be used by any other process.  Successive calls to (tmpnam) will return different pathnames.

 -- Procedure: current-error-port
     Returns the current port to which diagnostic and error output is directed.

 -- Procedure: force-output
 -- Procedure: force-output port
     Forces any pending output on PORT to be delivered to the output device and returns an unspecified value.  The PORT argument may be omitted, in which case it defaults to the value returned by (current-output-port).

 -- Procedure: output-port-width
 -- Procedure: output-port-width port

     Returns the width of PORT, which defaults to (current-output-port) if absent.  If the width cannot be determined 79 is returned.

 -- Procedure: output-port-height
 -- Procedure: output-port-height port

     Returns the height of PORT, which defaults to (current-output-port) if absent.  If the height cannot be determined 24 is returned.

System
======

These procedures are provided by all implementations.

 -- Function: identity x
     IDENTITY returns its argument.

     Example:

          (identity 3)
             => 3
          (identity '(foo bar))
             => (foo bar)
          (map identity LST)
             == (copy-list LST)

 -- Procedure: slib:load-source name
     Loads a file of Scheme source code from NAME with the default filename extension used in SLIB.  For instance if the filename extension used in SLIB is .scm then (slib:load-source "foo") will load from file foo.scm.

 -- Procedure: slib:load-compiled name
     On implementations which support separtely loadable compiled modules, loads a file of compiled code from NAME with the implementation's filename extension for compiled code appended.

 -- Procedure: slib:load name
     Loads a file of Scheme source or compiled code from NAME with the appropriate suffixes appended.  If both source and compiled code are present with the appropriate names then the implementation will load just one.  It is up to the implementation to choose which one will be loaded.

     If an implementation does not support compiled code then slib:load will be identical to slib:load-source.

 -- Procedure: slib:eval obj
     eval returns the value of OBJ evaluated in the current top level environment.

 -- Procedure: slib:eval-load filename eval
     FILENAME should be a string.  If filename names an existing file, the Scheme source code expressions and definitions are read from the file and EVAL called with them sequentially.  The slib:eval-load procedure does not affect the values returned by current-input-port and current-output-port.

 -- Procedure: slib:error arg1 arg2 ...
     Outputs an error message containing the arguments, aborts evaluation of the current form and responds in a system dependent way to the error. Typical responses are to abort the program or to enter a read-eval-print loop.

 -- Procedure: slib:exit n
 -- Procedure: slib:exit
     Exits from the Scheme session returning status N to the system. If N is omitted or #t, a success status is returned to the system (if possible).  If N is #f a failure is returned to the system (if possible).  If N is an integer, then N is returned to the system (if possible).  If the Scheme session cannot exit an unspecified value is returned from slib:exit.

Optional SLIB Packages
**********************

Several Scheme packages have been written using SLIB.  There are several reasons why a package might not be included in the SLIB distribution:

  * Because it requires special hardware or software which is not universal.

  * Because it is large and of limited interest to most Scheme users.

  * Because it has copying terms different enough from the other SLIB packages that its inclusion would cause confusion.

  * Because it is an application program, rather than a library module.

  * Because I have been too busy to integrate it.

Once an optional package is installed (and an entry added to *catalog*, the require mechanism allows it to be called up and used as easily as any other SLIB package.  Some optional packages (for which *catalog* already has entries) available from SLIB sites are:

SLIB-PSD is a portable debugger for Scheme (requires emacs editor).

          ftp-swiss.ai.mit.edu:pub/scm/slib-psd1-3.tar.gz
          prep.ai.mit.edu:pub/gnu/jacal/slib-psd1-3.tar.gz
          ftp.maths.tcd.ie:pub/bosullvn/jacal/slib-psd1-3.tar.gz
          ftp.cs.indiana.edu:/pub/scheme-repository/utl/slib-psd1-3.tar.gz

     With PSD, you can run a Scheme program in an Emacs buffer, set breakpoints, single step evaluation and access and modify the program's variables. It works by instrumenting the original source code, so it should run with any R4RS compliant Scheme. It has been tested with SCM, Elk 1.5, and the sci interpreter in the Scheme->C system, but should work with other Schemes with a minimal amount of porting, if at all. Includes documentation and user's manual.  Written by Pertti Kellom\"aki, pk@cs.tut.fi.  The Lisp Pointers article describing PSD (Lisp Pointers VI(1):15-23, January-March 1993) is available as

          http://www.cs.tut.fi/staff/pk/scheme/psd/article/article.html

SLIB-SCHELOG is an embedding of Prolog in Scheme.

          ftp-swiss.ai.mit.edu:pub/scm/slib-schelog.tar.gz
          prep.ai.mit.edu:pub/gnu/jacal/slib-schelog.tar.gz
          ftp.maths.tcd.ie:pub/bosullvn/jacal/slib-schelog.tar.gz
          ftp.cs.indiana.edu:/pub/scheme-repository/utl/slib-schelog.tar.gz

Procedure and Macro Index
*************************

This is an alphabetical list of all the procedures and macros in SLIB.

Variable Index
**************

This is an alphabetical list of all the global variables in SLIB.